// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare marrom = 
  texture{
    pigment{ color rgb < 1, 0.51, 0.23 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare verde = 
  texture{
    pigment{ color rgb < 0, 1, 0 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare solo = 
  texture{
    pigment{ color rgb < 0, 0.8, 0 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare cones = 
  cone {
    < 0, 0, -0.6 >,
		0.2,
    < 0, 0, 0.6 >,
    0.3
  }
 
#declare cabeca = 
  cone {
    < 0, 0, -0.8 >,
		0.4,
    < 0, 0, 0.8 >,
    0.7
  }

#declare pescoco = 
  cone {
    < 0, 0, -0.3 >,
		0.4,
    < 0, 0, 0.3 >,
    0.6
  }

#declare corpo = 
  cone {
    < 0, 0, -1.5 >,
		0.55,
    < 0, 0, 1.5 >,
    0.55
  }

#declare bolas = 
  sphere {
    < 0, 0, 0 >,
    0.3
  }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

// ======================================================================

object{ chao  translate < 0,0,-5 > texture{ solo } }

#macro pe()
	union
	{
		object { bolas texture { marrom } }
		object { cones rotate 90 *x translate < 0, 0.8, 0> texture { marrom } }
	}
#end

#macro subperna(A)
	union {
		object{ pe() rotate A *x scale < 0.8, 0.8, 0.8 > translate < 0, 1.6, 0 >}
		object{ pe() }
	}
#end

#macro perna(A, B)
	union {
		object{ subperna(A) rotate B *x scale < 0.8, 0.8, 0.8 > translate < 0, 1.6, 0> }
		object{ pe() }
	}
#end


#macro gato(A1, B1, C1, A2, B2, C2, A3, B3, C3, A4, B4, C4)
	union {
		object { perna(A1, B1) rotate C1 *x translate < 0.8, 0, 0 > }
		object { perna(A2, B2) rotate C2 *x translate < -0.8, 0, 0 > }

		object { perna(A3, B3) rotate C3 *x scale < 0.8, 0.8, 0.8 > translate < 0.8, 3, 0 > }
		object { perna(A4, B4) rotate C4 *x scale < 0.8, 0.8, 0.8 > translate <-0.8, 3, 0 > }

		object { pescoco rotate 175 *x translate < 0, 3.1, 1.6 > texture { marrom } }
		object { cabeca rotate 70 *x translate < 0, 3.6, 2.3 > texture { marrom } }
		object { corpo rotate 88 *x scale < 1.5, 1.5, 1.5 > translate < 0, 1.5, 0.8  > texture { marrom } }
	}
#end

object { gato(120, -90, -45, 120, -90, -45, 50, 20, -100, 50, 20, -100) translate < 0, -6, 0 > }
object { gato(120, -40, -150, 120, -40, -150, -10, 20,-30, -10, 20, -30) translate < 0, 2, 0 > }


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 1, 0, 0.2 >;
#declare dist_camera = 50.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)