// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.2 roughness 0.005 }
  }

#declare tx_verde = 
  texture{
    pigment{ color rgb < 0.48, 0.99, 0.00 > }
  };

#declare tx_cinza_escuro = 
  texture{
    pigment{ color rgb < 0.2, 0.2, 0.2 > }
  };

#declare tx_vermelho = 
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.00 > }
  }

#declare tx_marrom = 
  texture{
    pigment{ color rgb < 0.92, 0.64, 0.51 > }
  };

#declare tx_branco = 
  texture{
    pigment{ color rgb < 1, 1, 1 > }
  };


#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.2*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.90, 0.90, 0.90 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:
#declare cone_branco =
	cone{
		<0, 0, 0>, 0.8,
		<0, 0, 1.5>, 0
		texture{ tx_branco }
	}

#declare esfera_branca = 
  sphere{ < 0,0,0 >, 1
		texture{ tx_branco }
	}

#declare caixa =
	box{
		<+5,+5,+3>,
		<-5,-5,-3>
		texture { tx_branco }
	}

#macro cabeca ()
	union{
		//cabeca
		object{ esfera_branca scale <3, 3, 3> }
		//bochecha E
		object{ esfera_branca scale <1.4, 1.4, 1.4> translate <2, 0.7, 0.2> }
		//bochecha D
		object{ esfera_branca scale <1.4, 1.4, 1.4> translate <2, -0.7, 0.2> }
		//olho E
		union {
			object{ esfera_branca scale <1.2, 1.2, 1.5> translate <1.6, 0.5, 0.8> }
			object{ esfera_branca scale <0.5, 0.5, 0.5> translate <2.2, 0.65, 1.5> texture{ tx_verde }}
		}
		//olho D
		union {
			object{ esfera_branca scale <1.2, 1.2, 1.5> translate <1.6, -0.5, 0.8> }
			object{ esfera_branca scale <0.5, 0.5, 0.5> translate <2.2, -0.65, 1.5> texture{ tx_verde }}
		}
		//orelha E
		difference {
				object { cone_branco }
				object { cone_branco translate <0.5, 0, 0> }
				translate < 0, 0, 2.8>
				rotate 35 *x
		}
		//orelha E
		difference {
				object { cone_branco }
				object { cone_branco translate <0.5, 0, 0> }
				translate < 0, 0, 2.8>
				rotate -35 *x
		}
		//nariz
		object{	esfera_branca scale <0.5, 0.7, 0.5> translate <2.8, 0, 1> texture{ tx_cinza_escuro }}
		//boca
		difference {
			object{ esfera_branca scale <1.4, 1.4, 1.4> translate <1.8, 0, -0.2>}
			object{ esfera_branca scale <1.2, 1.2, 1.2> translate <4, 0, -0.2> texture{ tx_vermelho }}
		}
	}
#end

#macro pata()
	union {
		difference {
			object { esfera_branca scale <1.5,1.5,1.5> }
			object { caixa translate <0,0,-3>}
		}
	}
#end

#macro corpo(maoDirRot, maoEsqRot, bracoDirRot, bracoEsqRot)
	union{
		object { cabeca() translate <0,0,4> scale<1.3, 1.3, 1.3>}
		object { esfera_branca scale <4, 4, 4>}
		object { braco(maoDirRot) rotate mod(bracoDirRot, 90) *z rotate 50 *x translate <0, 3, 0.5>}
		object { braco(maoEsqRot) rotate mod(bracoEsqRot, 90) *z rotate 50 *x scale<1, -1, 1> translate <0, -3, 0.5>}
		object { coxa(0,0) rotate 20 *x translate <0, 1, -1>}
		object { coxa(0,0) rotate -20 *x translate <0, -1, -1>}
	}
#end

#macro braco(pataRot)
	union{
		object { esfera_branca scale <1.5, 3, 1.5> translate <0, 1.5, 0>}
		object { pata() rotate 90 *x rotate  mod(pataRot, 60) *z translate <0, 5.5, 0>}
	}
#end

#macro coxa(peRot, pernaRot)
	union {
		object { esfera_branca scale <2,2,3> translate <0,0,-3>}
		object { perna(peRot) rotate mod(pernaRot, 90) *y translate <0,0,-3.5>}
	}
#end

#macro perna(peRot)
	union {
		object { esfera_branca scale <1.5, 1.5, 2> translate <0, 0, -2.5>}
		object { pata() rotate mod(peRot, 30) *x translate <0,0,-5.5>}
	}
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
//  object{ chao }

	//object{ cabeca() }
	//object { braco(0) }
object{ corpo(-30, -30, -60, -60) scale <0.5, 0.5, 0.5>}

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 20.0;
#declare dir_camera = < 7.00, -3.00, 3.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)