// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#macro cabeca()
union
{
    sphere{< 0.00, 0.00, 0.00 >, 1 texture{ tx_fosca }  }
    cone  {<0,0,0>,0.3,<0,0,.8>,0.0  texture{ tx_fosca }  translate <0,-.3,.8>  }
    cone  {<0,0,0>,0.3,<0,0,.8>,0.0  texture{ tx_fosca }  translate <0,+.3,.8>  }		
}
#end

#macro corpo()
 cylinder{
    < 0.00, 0.00, 0.00 >,
    < 0.00, 0.00, 2.00 >,
    0.6
    texture{ tx_fosca }
}
#end

#macro coxa()
  cylinder{
    < 0.00, 0.00, 0.00 >,
    < 0.00, 0.00, 1.00 >,
    0.2
    texture{ tx_fosca }
  }
#end

#macro canela()
  cylinder{
    < 0.00, 0.00, 0.00 >,
    < 0.00, 0.00, 1.00 >,
    0.2
    texture{ tx_fosca }
  }
#end 
 

#macro pe ()
  cylinder{ 
	  < 0.00, 0.00, 0.00 >, 
	  < 0.00, 0.00, .5 >,  
	  0.2  
	  texture{ tx_fosca } 
	  rotate <0,90,0> 
	  }
#end

#macro subperna(angulo)
union
{
    object {canela() translate <0,0,-1> }
    object {pe() rotate<0,angulo,0> translate <0,0,-1>}
}
#end



#macro perna (angulo1,angulo2)
union
{
  object {coxa() translate <0,0,-1>   }
  object {subperna(angulo1) rotate <0,angulo2,0> translate <0,0,-1> }
}
#end

#macro mao()
  sphere
    {
    < 0.00, 0.00, 0.00 >, .3 
    texture{ tx_plastico }
    }
#end

#macro antebraco()
cylinder
    {
    < 0.00, 0.00, 0.00 >,
    < 0.00, 1.0, 0.00 >,
    0.2
    texture{ tx_fosca }
    }
#end

#macro subbraco(angulo)
union
{
  object { mao() rotate <0,0,angulo>  translate<0,.8,0> }
  object {antebraco()}
}
#end


#macro boneco (a1,a2,a3,a4,a5,a6,a7,a8,a9,a10)
union
{
  object {corpo()}
  object {cabeca() translate <0,0,2>}
  object {subbraco(a1) rotate<0,0,a2> translate <0,.6,0.5>}
  object {subbraco(a3) rotate<0,0,a4> translate <0,.6,0.5> scale <1,-1,1>}
  object {perna (a5,a6) rotate<0,0,a7> translate <0,-.4,0>}
  object {perna (a8,a9) rotate<0,0,a10> translate <0,-.4,0> scale <1,-1,1>}
}
#end


// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:
  
 
#declare bola =
  sphere{
    < 0.00, 0.00, 0.00 >, raio 
    texture{ tx_plastico }
  }
  
#declare pino = 
  cylinder{
    < -2.00, +2.00, -1.00 >,
    < +2.00, -2.00, +1.00 >,
    0.75
    texture{ tx_fosca }
  }
  
#declare furo = 
  cylinder{
    < -1.00, -2.00, -2.00 >,
    < +1.00, +2.00, +2.00 >,
    0.75*raio
    texture{ tx_fosca }
  }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

  
  object{ eixos(3.00) }

  //subperna (45)
  //perna(0,45)	
  //subbraco(30)
  object {boneco(0,0,0,0,0,0,0,0,0,0)}

  object {boneco(45,21,13,54,12,45,45,45,45,12) translate<0,4,0> }


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)