// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_preto = 
  texture{
    pigment{ color rgb < 0, 0, 0 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 0.84, 0.84, 0.84 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ==================

// DESCRIÇÃO DA CENA 

// Partes da cena:

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

#macro antebraco() 

	cylinder{ < 0, 0, 0 >, < 0, 1, 0 >, 0.3 texture{ tx_fosca } }

#end

#macro braco(ang1) 
	union {	cylinder{ < 0, 0, 0 >, < 0, 1, 0 >, 0.3 texture{ tx_fosca } }
		object { antebraco() rotate x*ang1 translate 1*y } }
#end

#macro pe() 

	cylinder{ < 0, 0, 0 >, < 1.5, 0, 0 >, 0.5 texture{ tx_preto } }

#end

#macro pernabaixo(ang1)
	union { cylinder{ < 0, 0, -2.00 >, < 0, 0, 0 >, 0.5 texture{ tx_fosca } }
		object { pe() rotate y*ang1 translate -2*z } }
#end

#macro pernacima(ang1, ang2)
	union { cylinder{ < 0, 0, -2 >, < 0, 0, 0 >, 0.5 texture{ tx_fosca } }
		object { pernabaixo(ang1) rotate y*ang2 translate -2*z } }
#end

#macro coelho1()

union { object { corpo () scale <2,2,2 > translate 5*z}
	object { pernacima (-15, 20) rotate y*40 translate -0.7*y }
	object { pernacima (-15, 20) rotate y*40 translate 0.7*y}
	object { braco (-30) rotate y*10 scale -1*y translate -0.5*y translate 2*z}
	object { braco (-30) rotate y*10 translate 0.5*y translate 2*z}
 }
#end	

#macro coelho2()

union { object { corpo () scale <2,2,2 > translate 5*z}
	object { pernacima (30, 15) rotate y*5 translate -0.7*y }
	object { pernacima (30, 15) rotate y*5 translate 0.7*y}
	object { braco (45) rotate x*40 scale -1*y translate -0.5*y translate 2*z}
	object { braco (45) rotate x*40 translate 0.5*y translate 2*z}
 }
#end	

#macro corpo()

union { sphere{ < 0,0,0 >, 0.60 texture{ tx_fosca } }
	cone { <0, -0.2, 0.5>, 0.2, <0, -0.2, 1.2>, 0  texture{ tx_fosca } }
	cone { <0, 0.2, 0.5>, 0.2, <0, 0.2, 1.2>, 0  texture{ tx_fosca } }
	cone { <0, 0, -0.6>, 0.2, <0, 0, -2.5>, 0.7  texture{ tx_fosca } }
 }
#end


object { coelho1() translate y*-3}
object { coelho2() translate y*4}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 11.0;
#declare dir_camera = < 20, 0, 5 >;
#declare dist_camera = 15.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)