// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.95, 0.70 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_nota =
  texture{
    pigment{ color rgb < 0.00, 0.80, 0.00 > }
  }

#declare tx_metal =
  texture{
        pigment{color rgb < 1.00, 0.00, 0.00 > }
         finish{ reflection 0.30 }
        }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare tx_xadrez2 =
  texture{
    pigment{ checker color rgb < 0.00, 0.00, 0.00 >, color rgb < 1.00, 1.00, 1.00 > }
    finish{ diffuse 1.0 ambient 1.0 }
    scale 5.0
  }

#declare NQ=6;
#declare angbra1z=array[NQ];
#declare angbra2z=array[NQ];
#declare angbra1y=array[NQ];
#declare angbra2y=array[NQ];
#declare angcoxa1x=array[NQ];
#declare angcoxa2x=array[NQ];
#declare angorelha1x=array[NQ];
#declare angorelha2x=array[NQ];
#declare fq = array[NQ];

#declare fq[0] = 0.0;
#declare fq[1] = 0.2;
#declare fq[2] = 0.4;
#declare fq[3] = 0.6;
#declare fq[4] = 0.8;
#declare fq[5] = 1.0;

#declare angbra1z[0]=0;
#declare angbra1z[1]=90;
#declare angbra1z[2]=0;
#declare angbra1z[3]=90;
#declare angbra1z[4]=90;
#declare angbra1z[5]=0;

#declare angbra2z[0]=0;
#declare angbra2z[1]=0;
#declare angbra2z[2]=-90;
#declare angbra2z[3]=-90;
#declare angbra2z[4]=-90;
#declare angbra2z[5]=0;

#declare angbra1y[0]=0;
#declare angbra1y[1]=0;
#declare angbra1y[2]=0;
#declare angbra1y[3]=-45;
#declare angbra1y[4]=0;
#declare angbra1y[5]=0;

#declare angbra2y[0]=0;
#declare angbra2y[1]=0;
#declare angbra2y[2]=0;
#declare angbra2y[3]=-45;
#declare angbra2y[4]=0;
#declare angbra2y[5]=0;

#declare angcoxa1x[0]=0;
#declare angcoxa1x[1]=0;
#declare angcoxa1x[2]=45;
#declare angcoxa1x[3]=0;
#declare angcoxa1x[4]=0;
#declare angcoxa1x[5]=0;

#declare angcoxa2x[0]=0;
#declare angcoxa2x[1]=-45;
#declare angcoxa2x[2]=0;
#declare angcoxa2x[3]=0;
#declare angcoxa2x[4]=0;
#declare angcoxa2x[5]=0;

#declare angorelha1x[0]=0;
#declare angorelha1x[1]=0;
#declare angorelha1x[2]=0;
#declare angorelha1x[3]=-90;
#declare angorelha1x[4]=0;
#declare angorelha1x[5]=0;

#declare angorelha2x[0]=0;
#declare angorelha2x[1]=0;
#declare angorelha2x[2]=0;
#declare angorelha2x[3]=90;
#declare angorelha2x[4]=0;
#declare angorelha2x[5]=0;

#macro tronco(angcoxa1x,angcoxa1y,angcoxa1z,angcanela1x,angcanela1y,angcanela1z,angpe1x,angpe1y,angpe1z,angcoxa2x,angcoxa2y,angcoxa2z,angcanela2x,angcanela2y,angcanela2z,angpe2x,angpe2y,angpe2z,angbraco1x,angbraco1y,angbraco1z,angantebraco1x,angantebraco1y,angantebraco1z,angmao1x,angmao1y,angmao1z,angbraco2x,angbraco2y,angbraco2z,angantebraco2x,angantebraco2y,angantebraco2z,angmao2x,angmao2y,angmao2z)
  union{
    sphere{
      < +0.00, +0.00, +10.00 >,
      4.00
    }
    object{coxa(angcanela1x,angcanela1y,angcanela1z,angpe1x,angpe1y,angpe1z) rotate <angcoxa1x,angcoxa1y,angcoxa1z> translate <0,+1.5,8>}
    object{coxa(angcanela2x,angcanela2y,angcanela2z,angpe2x,angpe2y,angpe2z) rotate <angcoxa2x,angcoxa2y,angcoxa2z> translate <0,-1.5,8>}
    object{braco(angantebraco1x,angantebraco1y,angantebraco1z,angmao1x,angmao1y,angmao1z) rotate <angbraco1x,angbraco1y,angbraco1z> translate <0,3.5,10>}
    object{braco(angantebraco2x,angantebraco2y,angantebraco2z,angmao2x,angmao2y,angmao2z) rotate <angbraco2x,angbraco2y,angbraco2z> translate <0,-3.5,10>}
  }
#end

#macro cabeca(angx1,angy1,angz1,angx2,angy2,angz2)
  union{
    sphere{
      < +0.00, +0.00, +15.4 >,
      1.50
    }
    cylinder{
        < +1.00, +0.00, 15.4 >,
        < +3.00, +0.00, 15.4 >,
        0.25
    }
    sphere{
        < +3.00, +0.00, +15.4 >,
        0.25
    }
    object {orelha() rotate <angx1,angy1,angz1> translate <0,1,16.4>}
    object{orelha() rotate <angx2,angy2,angz2> translate <0,-1,16.4>}
  }
#end

#macro orelha()
    union{
      cylinder{
        < +0.00, +0.00, -0.20 >,
        < +0.00, +0.00, 3.00 >,
        0.25
      }
      sphere{
        < +0.00, +0.00, +3.00 >,
        0.25
      }
    }
#end

#macro pe()
    box{
      <0,-0.5,-0.13>,
      <2,+0.5,+0.13>
    }
#end

#macro canela(angx,angy,angz)
    union{
      cylinder{
        <0,0,-4>,
        <0,0,0>
        0.5
      }
      object{pe() rotate <angx,angy,angz> translate <0,0,-4>}
    }
#end

#macro coxa(angcanelax,angcanelay,angcanelaz,angpex,angpey,angpez)
    union{
      cone{
        <0,0,-7>, 0.6
        <0,0,0> , 1
      }
      sphere{
        <0,0,-7>,
        0.6
      }
      object{canela(angpex,angpey,angpez) rotate <angcanelax,angcanelay,angcanelaz> translate <0,0,-7.0>}
    }
#end

#macro braco(angantebracox,angantebracoy,angantebracoz,angmaox,angmaoy,angmaoz)
    union{
      cylinder{
        <0,0,0>,
        <3,0,0>
        0.5
      }
      sphere{
        <3,0,0>,
        0.5
      }
      object{antebraco(angmaox,angmaoy,angmaoz) rotate <angantebracox,angantebracoy,angantebracoz> translate <3,0,0>}
    }
#end

#macro antebraco(angmaox,angmaoy,angmaoz)
    union{
      cylinder{
        <0,0,0>,
        <3,0,0>
        0.5
      }
      object{mao() rotate <angmaox,angmaoy,angmaoz> translate <3,0,0>}
    }
#end

#macro mao()
    union{
      sphere{
        <1,0,0>,
        1
      }
      cylinder{
        < +1.00, +0.00, -0.00 >,
        < +2.00, +1.00, 0.00 >,
        0.25
      }
      sphere{
        < +2.00, +1.00, 0.00 >,
        0.25
      }
      cylinder{
        < +1.00, +0.00, -0.00 >,
        < +2.50, +0.00, 0.00 >,
        0.25
      }
      sphere{
        < +2.50, +0.00, 0.00 >,
        0.25
      }
      cylinder{
        < +1.00, +0.00, -0.00 >,
        < +2.00, -1.00, 0.00 >,
        0.25
      }
      sphere{
        < +2.00, -1.00, 0.00 >,
        0.25
      }
    }
#end

#macro interpola(f0,v0,f1,v1,f)
#local s1 = (f-f0)/(f1-f0);
#local s2 = 1-s1;
(s2*v0+s1*v1)
#end

#macro quadroant(fase)
#local i = 0;
#while (i<NQ-1)
  #if((fase>=fq[i]) & (fase<=fq[i+1]))
    #local resp=i;
  #end
  #local i = i+1;
#end
resp
#end

#macro danca(fase)
  #local i = quadroant(fase);
  #local braco1z = interpola(fq[i], angbra1z[i],fq[i+1],angbra1z[i+1],fase);
  #local braco2z = interpola(fq[i], angbra2z[i],fq[i+1],angbra2z[i+1],fase);
  #local braco1y = interpola(fq[i], angbra1y[i],fq[i+1],angbra1y[i+1],fase);
  #local braco2y = interpola(fq[i], angbra2y[i],fq[i+1],angbra2y[i+1],fase);
  #local coxa1x = interpola(fq[i], angcoxa1x[i],fq[i+1],angcoxa1x[i+1],fase);
  #local coxa2x = interpola(fq[i], angcoxa2x[i],fq[i+1],angcoxa2x[i+1],fase);
  #local orelha1x = interpola(fq[i], angorelha1x[i],fq[i+1],angorelha1x[i+1],fase);
  #local orelha2x = interpola(fq[i], angorelha2x[i],fq[i+1],angorelha2x[i+1],fase);
  union{
    object{ tronco(coxa1x,0,0,0,0,0,0,0,0,coxa2x,0,0,0,0,0,0,0,0,0,braco1y,braco1z,0,0,0,0,0,0,0,braco2y,braco2z,0,0,0,0,0,0) texture{tx_fosca}}
    object{ cabeca(orelha1x,0,0,orelha2x,0,0) texture{tx_fosca} }
  }
#end

#declare chao =
        box{
                <+20.00,-20.00,-1.00>,
                <-20.00,+20.00,-0.00>
        }

#include "eixos.inc"

union{
  object{danca(clock)}
  object{chao texture{tx_xadrez2} translate <0,0,-4>}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 8.00 >;
#declare raio_cena = 40.0;
#declare dir_camera = < 8, 0, 0.00 >;
#declare dist_camera = 60.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)