// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

#include "colors.inc"

background{ color rgb < 0.75, 0.80, 0.85 > }


// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#declare bola = 
  sphere {
    <0,0,0>, 0.6
    pigment { color Green }
  }

#declare bastao = 
  cylinder {
    <0,0,0>, <0,0,0.5>, 0.25 
    pigment { color Green }
  }

#declare pino =
  union{
    object { bola }
    object { bastao translate <0,0,0.4> }
  }

#declare roleta = seed(417);

#macro bit(valor, def)
  #if(def=1)
    object { pino rotate 90*x}
  #else 
    #if(valor=1)
      object { pino }
    #else 
      #if(valor=0)
	object { pino rotate 180*x}
      #end
    #end
  #end
#end


#macro fileira(n, valor, prob)
  #local nv = valor;
  #local i = 0;

  union {
    #while(i < n)
      #local def = (rand(roleta) < prob );
      object { bit(mod(nv,2), def) translate <(2*i)-2,0,0> }
      #local nv = int(nv/2);
      #local i = i+1;
    #end
  }
#end

#macro moldura(m, n, j) 
  box {
      <-n, -j,-m>, <n,j,m>
      pigment { color Black }
  }
#end

#macro suporte(n)  
  cylinder {
    <-n,0,0>, <n,0,0>, 0.25
    pigment { color  Black }
  }
#end

#macro abaco(m, n, valores, prob)
  #local i = 0;
  
  union{
    #while(i < m)
      object {
	union {
	  object { fileira(n, valores[i], prob) }
	  object { suporte(n+1) }
	} 
	translate <0,0,m-1-2*i>
      }	
      #local i = i+1;
    #end
  
    difference {
      object { moldura(m+1.5,n+1.5,1) }
      object { moldura(m+1,n+1,2) }
    }
  }

#end

// Aqui está a cena, finalmente:
#declare vetor = array[3];
#declare vetor[0] = 3;
#declare vetor[1] = 7;
#declare vetor[2] = 6;

#declare vetor1 = array[3];
#declare vetor1[0] = 2;
#declare vetor1[1] = 5;
#declare vetor1[2] = 1;

object { abaco(3, 4, vetor, 0.08) translate <0,0,-5>}
object { abaco(3, 3, vetor1, 0.08) translate <0,0,5>}


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 17.0;
#declare dir_camera = <0,1,0>;//< 14.00, 7.00, 4.00 >;
#declare dist_camera = 50.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)