// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 1 ambient 1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 0.50, 0.50, 0.50 > }
    finish{ diffuse 0.2 reflection 0.7*< 0.50, 0.50, 0.50 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:
			
#declare valores=array[10];
#declare valores[0]=1;  
#declare valores[1]=12;
#declare valores[2]=11;
#declare valores[3]=15;
#declare valores[4]=3;
#declare valores[5]=5;  
#declare valores[6]=38;
#declare valores[7]=21;
#declare valores[8]=3;
#declare valores[9]=5;
 
#macro bit (valor,defeito)
	#if (defeito=0)
	#if (valor =1)
	cone{<0,0,0>,0.3,<0,0,0.5>,0
			pigment{ color rgb<0.2,0.2,0.7>}}
	#else
	cone{<0,0,0>,0,<0,0,0.5>,0.3
			pigment{ color rgb<0.2,0.2,0.7>}}
	#end
	#else
	box{<-0.3,-0.3,0><0.3,0.3,0.5>}
	#end
#end

#macro quadro(l,a) 
	difference{
		box{<-0.3, -l/2-2, -a/2-2>, <0.3, l/2+2, a/2+2> pigment{ color rgb<0.7,0.5,0.0>}}
		box{<-2, -l/2, -a/2>, <2, l/2, a/2>pigment{ color rgb<0.7,0.5,0.0>}}
	}
#end

#declare roleta = seed(417);
#macro fileira(n, valor, l,prob,alt)//numero de bits, valor do numero, largura da fileira,prob de errro, altura
	union{
	
	#local i=0;
	#local vv=valor;
	#while (i < n)
		#local defeito = (rand(roleta) <= prob);
		#local ubit=mod(vv,2);
		object{bit(ubit,defeito) translate<0,(l/2)-i*(l/(n-1)),alt>}
		#local i = i+1;
		#local vv=int(vv/2);
	#end
	}
#end

#macro abaco(m,n,valores,prob)
	union{

	object{quadro(2*n, 2*m)}
	#local i=0;
	#while(i<m)
		object{fileira(n,valores[i],(2*n-2),prob,m-1-i*(m/(m-1)))}
		#local i=i+1;
	#end
	}
#end



#include "eixos.inc"

// cena

union{
	//object{ eixos(3.00) }
	

	object{abaco(10,10,valores,0.1)translate<0,-10,0>}
	object{abaco(5,5,valores,0.5) translate<0,10,0>}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 30.0;
#declare dir_camera = < 14.00, 3.00, 8.00 >;
//#declare dir_camera = < 1.00, 4.00, 0.00 >;
#declare dist_camera = 100.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)