// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
  
#declare bola =
  sphere{
            < 0.00, 0.00, 0.0 >, 1
            texture{ tx_xadrez}
  }
    
#declare eixo =
  union{

  cylinder{ < 0, 0, 0.00 >,< 0, 0, +7.00 >,0.25
    texture{tx_plastico }
  }
  
  cylinder{ < 0, -3.5, 0.00 >,< 0, 3.5, 0.00 >,0.25
    texture{tx_plastico }
  } 
  
 }

// ======================================================================
// DESCRIÇÃO DA CENA 

#macro bit(valor,defeito)

    union{
        object{eixo}
        
        
        #if (defeito)
        
            #if (valor = 0)
                object{bola translate<0,0,2> texture{tx_fosca}}
            
            #else
                object{bola translate<0,0,5> texture{tx_fosca}}
                
            #end
        
        #else
        
            #if (valor = 0)
                object{bola translate<0,0,2>}
            
            #else
                object{bola translate<0,0,5>}
                
            #end
        
        #end
    }
#end

#macro fileira(n,valor)

    #local i = 0;
    union{
    #while(i<n)

        object{bit(mod(valor,2),1) translate<0,-2*i,0>}
        #local valor =  int(valor/2);

        #local i = i+1;
        
    #end
    }
#end

#declare valores = array[10]
#declare valores[0] = 2;
#declare valores[1] = 4;
#declare valores[2] = 6;
#declare valores[3] = 8;
#declare valores[4] = 10;
#declare valores[5] = 12;
#declare valores[6] = 14;
#declare valores[7] = 16;
#declare valores[8] = 18;
#declare valores[9] = 20;


#macro abaco(m,n,valores)

    #local i = 0;
    union {
    #while (i<m)
    
        #if(i<10)
            object{ fileira( n,valores[i] ) translate<0,0,-7*i>}
        
        #else
            object{fileira( n,0 ) translate<0,0,-7*i>}
            
        #end
    
        #local i = i+1;
    #end
    }
#end


object{abaco(10,10,valores) rotate<0,-10,30> translate<0,0,18>  }


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 80.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)