// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.4, 0.6, 0.8 > }

#declare tx_pele = 
  texture{
    pigment{ color rgb < 0.70, 0.70, 0.70 > }
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#include "textures.inc"

#declare botao = union{
  box{<0.5,0.05,0.4>, <-0.5,-0.05,0> pigment{ color rgb < 0.20, 0.80, 0.20 > }}
  cylinder{<0,0,0>, <0,0,0.15>, 0.5  pigment{ color rgb < 0.90, 0.70, 0.30 > }}
}

#macro bit(valor, defeito, prob) 
  #if(defeito>prob)
    object{botao rotate<0,0,90*valor>}
  #else
    union{
      object{botao rotate<0,0,0>}
      object{botao rotate<0,0,90>}
    }
  #end
#end

#macro linha(n, valor, prob) 
  union{
    #local i = 0;
    #while (i < n)
      object{bit(mod(valor,2), rand(semente), prob) translate<2*i-n+1, 0, 0>}
      #declare i = i + 1;
      #declare valor = int(valor/2);
    #end
  }
#end

#macro abaco(m, n, valores, prob)
  union{
    #local i = 0;
    #while (i < m)
      object{linha(n, valores[i], prob) translate<0, 2*i-m+1, 0>}
      #declare i = i + 1;
    #end
    difference{
      box{<n+0.5, m+0.5, 0.5>, <-n-0.5, -m-0.5, -0.1> pigment{ color rgb < 0, 0, 1 > }}
      box{<n, m, 0.51>,        <-n, -m, 0>            pigment{ color rgb < 1, 1, 1 > }}
    }
  }
#end

#declare lista=array[15];
#declare lista[0]=255;
#declare lista[1]=213;
#declare lista[2]=165;
#declare lista[3]=032;
#declare lista[4]=065;
#declare lista[5]=026;
#declare lista[6]=001;
#declare lista[7]=045;
#declare lista[8]=011;
#declare lista[9]=169;
#declare lista[10]=254;
#declare lista[11]=019;
#declare lista[12]=110;
#declare lista[13]=005;
#declare lista[14]=084;

#declare semente = seed(417);

// ======================================================================
// IBAGENS

#include "eixos.inc"

// Aqui está a cena, finalmente:
union{
  object{abaco(3, 7, lista, 0.1) translate<0,5,0>}
  object{abaco(5, 5, lista, 0.5) translate<0,-5,0>}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.01, -1.00 >;
#declare raio_cena = 20.0;
#declare dir_camera = < 0.00, 0.01, 20.00 >;
#declare dist_camera = 30.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)