// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }
#include "textures.inc"
#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare valores = array[10];
#declare valores[0] = 2;
#declare valores[1] = 12;
#declare valores[2] = 11;
#declare valores[3] = 10;
#declare valores[4] = 5;
#declare valores[5] = 15;
#declare valores[6] = 13;
#declare valores[7] = 8;
#declare valores[8] = 7;
#declare valores[9] = 1;



#macro bit (valor, defeito)
   union {
      cylinder {<0,0,0> <0,0,0.1> 0.3}
      
      #if (valor=1)
         cylinder {<0,0,0> <0,0.3,0.3> 0.1}
      #else
         #if(defeito=1)
            cylinder {<0,0,0> <0,0,0.3> 0.1}
         #else
            cylinder {<0,0,0> <0,-0.3,0.3> 0.1}
         #end
      #end
   } texture {tx_espelho}
#end

#macro fileira (n, valor, prob)
   #declare roleta=seed(231241);
   #local i = 0;
   union {
   #while (i<n)
      object{ bit( mod(valor,2), (rand(roleta) < prob) ) translate <i,0,0> }
      #local valor = int(valor/2);
      #local i = i+1;
   #end
   }
#end

#macro abaco(m, n, vals, prob)
   #local i=0;
   union {
      object {difference {
         box {<-2,2,0.5> <n+1, -m-1,-0.5>}
         box {<-1,1,2> <n, -m,-2>}
      } texture {Cherry_Wood}
      }
      box {<-1,1,0> <n, -m,-0.3> texture {tx_vidro}}
      #while (i<m)
         object {fileira(n, vals[i], prob) translate <0,-i,0>}
         #local i = i+1;
      #end
   }

#end

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }



#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  //object{ eixos(3.00) }
  //object{ chao  translate < 0,0, 0 > texture{ tx_xadrez } }
  union {
	object{abaco(10,6,valores, 0.3)}
  }
}



	 
#include "camlight.inc"

#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 0.00, 5.00, 3.00 >;
#declare dist_camera = 25.0;
#declare intens_luz = 1.25;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)