// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#include "eixos.inc"

//Programa

#declare valores = array[10]
#declare valores[0] = (1-clock)*4+clock*12;
#declare valores[1] = (1-clock)*1+clock*2;
#declare valores[2] = (1-clock)*5+clock*8;
#declare valores[3] = (1-clock)*2+clock*10;
#declare valores[4] = (1-clock)*8+clock*12;
#declare valores[5] = (1-clock)*2+clock*4;
#declare valores[6] = (1-clock)*5+clock*7;
#declare valores[7] = 6;
#declare valores[8] = 2;
#declare valores[9] = 5;

#declare roleta = seed(417);


#macro moldura(ncolunas,bits_coluna)

difference{
  box{
		< -4, -0.5, 0>,
	     	<  (0.6)*(ncolunas+1), 0.5, (8/9)*bits_coluna>
		texture{ tx_fosca }
  	  }

  box {
		< -3.5,-1.1, 0.5>,
		<  0.6*ncolunas, 1.1, (7.5/9)*bits_coluna>
		texture{ tx_fosca }
	  }
}
#end

#macro bit(valor,def)
#if(def=0) 
  union{
    sphere {
  		<0,0,0>
		0.25
		texture{ tx_espelho }
    }
    box {
		< 0 ,-0.1,-0.1>
		<0.4, 0.1, 0.1>
		texture{ tx_xadrez }
		rotate z*(valor*90)
    }
  }
#else
  union{
    sphere {
  		<0,0,0>
		0.25
		texture{ tx_espelho }
    }
    box {
		< 0 ,-0.1,-0.1>
		<0.4, 0.1, 0.1>
		texture{ tx_xadrez }
		rotate z*(valor*45)
    }
  }
#end
#end

#macro coluna(nbits,num,prob)
#local resto=0;
#local num_aux = num;
#local nbits_aux = nbits;
#local r = int(num);
#local f = num - r;

union{
  #while(nbits_aux>0)
    #local def = (rand(roleta) < prob);

    #local resto = mod(num_aux,2);
    #if(resto=0)
      #local bitr = f;
      #local f = 0;
    #else
      #local bitr = 1-f;
    #end

    #local num_aux = int(num_aux/2);
    #local nbits_aux = nbits_aux - 1;
    object { bit(bitr,def) translate <0,0,nbits_aux*0.75 + 1> }
  #end
}

#end

#macro abaco(ncolunas,bits_coluna,valores,prob)
#local i=0;

union{
  object{moldura(ncolunas,bits_coluna)}
  #while(i<ncolunas)
    object{ coluna(bits_coluna, valores[i],prob)  translate<i-3,0,0> }
    #local i = i + 1;
  #end
}

#end

object{ eixos(3.00) }
object{abaco(8,5,valores,0.4)}


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 14.0;
#declare dir_camera = < 2.00, 3.00*clock, 1.00*clock >;
#declare dist_camera = 14.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)