// Exemplo de arquivo de descricao de cena para POV-ray

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 1.00, 1.00, 1.00 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.71, 0.45, 0.19 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_plastico2 = 
  texture{
    pigment{ color rgb < 0.99, 0.0, 0.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
#declare tx_xadrez2 =
  texture{
    pigment{ checker color rgb < 0.60, 0.32, 0.10 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.65, 1.00 > filter 0.50 }
    finish{ diffuse 0.03 ambient 0.02 specular 0.25 roughness 0.005 }
  }

// ======================================================================
// DECLARAÇÃO DE OBJETOS

#declare raio = 2.000;

// Partes da cena:

#include "eixos.inc"
  
#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#declare caixa_ext =
  box { <0,0,0>, <1,5,2> }
#declare caixa_int =
  box { <-0.5,0.1,0.1>, <+1.5,4.9,1.9> }
#declare pino =
  cylinder { <0,0,0>, <0,0,2>, 0.1 }
#declare conta =
  sphere { <0,0,0>, 0.2 }

#declare valores=array[5];
#declare valores[0] = (1-clock)*0+(clock)*10;
#declare valores[1] = (1-clock)*32+clock*64;
#declare valores[2] = (1-clock)*65+clock*96;
#declare valores[3] = (1-clock)*145+clock*583;
#declare valores[4] = (1-clock)*65+clock*13;

#declare roleta = seed(186);

// ======================================================================
// DESCRIÇÃO DE MACROS

#macro bit(valor,defeito)
union{
  #local pos=-1;
  #if (defeito)
    object{ pino translate<0.3,0,0> texture{tx_vidro} }
  #else
    object{ pino translate<0.3,0,0> texture{tx_plastico} }
    object{ conta translate<0.3,0,(valor+0.4)*1.2> texture{tx_plastico2} }
  #end
}
#end

#macro fileira(n,valor,prob)
union{
  difference{
	object{ box { <0,0,0>, <0.6,0.55*n+0.6,2> } }
	object{ box { <-0.5,0.1,0.1>, <1,0.55*n+0.5,1.9> } }
	texture{tx_plastico}
  }
  #local i = n;
  #local r = int(valor);
  #local f = valor-r;
  #while(i > 0)  
    #local vv= mod(r,2);
    #local def=(rand(roleta) < prob);
    #if (vv=0)
      object{ bit(f,def) translate<0,0.55*i,0> }
      #local f = 0;
    #else
      object{ bit(1-f,def) translate<0,0.55*i,0> }  
    #end    
    #local r = int(r/2);
    #local i = i-1;
  #end
}
#end

#macro abaco(m,n,valor,prob)
union{
  #local i=0;
  #while(i != m)
    object{ fileira(n,valor[i],prob) translate<0,-(0.55*n+0.6)/2,2*i> }
    #local i=i+1;
  #end
}
#end

// ======================================================================
// ANIMAÇÃO

// ======================================================================
// DESCRIÇÃO DA CENA 

union{
  object{ chao translate < 0,0,-10 > texture{tx_xadrez} }
  object{ abaco(2,8,valores,0.004) translate<0,0,-2> scale<1.5,1.5,1.5>}
  //object{ abaco(5,4,valores,0.05) translate<0,3,-3> }

  //object{ eixos(4) }

}


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 12;
#declare dir_camera = < -5*cos(clock*2*pi), 5*sin(clock*2*pi), 0.00 >;
#declare dist_camera = 11.00;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)