// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
  
#declare bola =
  sphere{
            < 0.00, 0.00, 0.0 >, 1
            texture{ tx_plastico}
  }
    
#declare eixo =
  union{

  cylinder{ < 0, 0, 0.00 >,< 0, 0, +7.00 >,0.25
    texture{tx_plastico }
  }
  
  cylinder{ < 0, -3.5, 0.00 >,< 0, 3.5, 0.00 >,0.25
    texture{tx_plastico }
  } 
  
 }
 
#declare roleta = seed(417);

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

// ======================================================================
// DESCRIÇÃO DA CENA 

#macro bit(valor,defeito)

    union{

        object{eixo}
        
        
        #if (defeito)
        
            #if (valor = 0)
                object{bola translate<0,0,2> texture{tx_fosca}}
            
            #else
                object{bola translate<0,0,5> texture{tx_fosca}}
                
            #end
        
        #else
        
            #if (valor = 0)
                object{bola translate<0,0,2>}
            
            #else
                object{bola translate<0,0,5*valor>}
                
            #end
        
        #end
    }
#end

#macro fileira(n,valor,prob)

    #local i = 0;
    #local r = int(valor);
    #local f = valor - r;
    union{
    #while(i<n)
        #local def = (rand(roleta) < prob);
    
        #local vb = mod(r,2);
        
        #if (vb = 0)
            #local bitk = f;
            #local f = 0;
            object{bit(mod(bitk,2),def) translate<0,-2*i,0>}
        
        #else
            #local bitk = 1 - f;
            object{bit(mod(bitk,2),def) translate<0,-2*i,0>}
        
        #end
        
        
        #local r =  int(r/2);
        #local i = i+1;
        
    #end
    }
#end

#declare valores = array[10]
#declare valores[0] = 2*clock+0*(1-clock);
#declare valores[1] = 4*clock+0*(1-clock);
#declare valores[2] = 6*clock+0*(1-clock);
#declare valores[3] = 8*clock+0*(1-clock);
#declare valores[4] = 10*clock+0*(1-clock);
#declare valores[5] = 12*clock+0*(1-clock);
#declare valores[6] = 14*clock+0*(1-clock);
#declare valores[7] = 16*clock+0*(1-clock);
#declare valores[8] = 18*clock+0*(1-clock);
#declare valores[9] = 20*clock+0*(1-clock);


#macro abaco(m,n,valores,prob)

    #local i = 0;
    union {
    #while (i<m)
    
        #if(i<10)
            object{ fileira( n,valores[i],prob ) translate<0,0,-7*i>}
        
        #else
            object{fileira( n,0,prob ) translate<0,0,-7*i>}
            
        #end
    
        #local i = i+1;
    #end
    }
#end

object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
object{abaco(10,10,valores,0.25) rotate<0,-10,30> translate<0,0,60>  }


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 200.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight( <10.00, 0.00+(10*clock+0*(1-clock)), 1.00 >, 200+(10*clock), dir_camera, dist_camera , z, intens_luz)