// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 2.000;
#declare esfera = sphere { <0,0,0> 0.5 }

#declare caixa = box { <0,0,0> <1,1,0.6> texture {tx_plastico} }

#declare valor=array[4]
#declare valor[0] = (1-clock) * 0 + clock * 10;
#declare valor[1] = (1-clock) * 11 + clock * 20;
#declare valor[2] = (1-clock) * 21 + clock * 30;
#declare valor[3] = (1-clock) * 30 + clock * 40;
#declare valor2=array[3]
#declare valor2[0] = (1-clock) * 15 + clock * 25;
#declare valor2[1] = (1-clock) * 25 + clock * 35;
#declare valor2[2] = (1-clock) * 35 + clock * 45;

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }
#declare roleta = seed(5487);

#macro chave(POSICAO, defeito)
  union{
    cylinder { <0,0,0> <0,0,2> 0.25 texture {tx_plastico}}
    #if (defeito = 0)
    object { esfera translate <0,0,2*POSICAO> texture {tx_plastico} }
    #else
    object { esfera translate <0,0,2*POSICAO> texture {tx_fosca} }
    #end
  }
#end

#macro caixagrande()
 difference {
   box { <0,0,0> <6,16,10> texture {tx_xadrez}}
   box { <-1.4,0,0> <6,14, 4> texture {tx_plastico} translate <1,1,0.5> }
   box { <-1.4,0,0> <6,14, 4> texture {tx_plastico} translate <1,1,5> }
   }
#end

#macro fileira(BITS, VALOR, PROBABILIDADE)

  #local AUX = 0;
  #local AUX_VALOR = 0;
  #local AUX_VALOR_PROX = 0;
  #local DEFEITO =0;
  #local AUX2 =0;
  #local FRACAO = 0;

  #local AUX_VALOR = int(VALOR);
  #local FRACAO = VALOR-AUX_VALOR;
  #local AUX_VALOR_PROX = AUX_VALOR+1;

union {

      #while(AUX<BITS)

        #local AUX2 = rand(roleta);
        #if (AUX2 < PROBABILIDADE)
        #local DEFEITO = 1;
        #else
        #local DEFEITO = 0;
        #end

        #if (FRACAO = 0)

          #if (mod(AUX_VALOR,2) = 0)
            object { chave(0, DEFEITO) translate <0, -AUX,0> }
          #else
            object { chave(1,DEFEITO) translate <0,-AUX,0> }
          #end

        #else

          #if (mod(AUX_VALOR,2) = 0)

            #if (mod(AUX_VALOR_PROX, 2) = 0)
            object { chave(0, DEFEITO) translate <0, -AUX,0> }
            #else
            object { chave(FRACAO, DEFEITO) translate <0, -AUX,0> }
            #end

          #else

            #if (mod(AUX_VALOR_PROX, 2) = 0)
            object { chave(1-FRACAO, DEFEITO) translate <0, -AUX,0> }
            #else
            object { chave(1, DEFEITO) translate <0, -AUX,0> }
            #end

           #end

        #end
          #local AUX_VALOR = int(AUX_VALOR/2);
           #local AUX_VALOR_PROX = int(AUX_VALOR_PROX/2);
          #local AUX = AUX+1;

      #end

 }
#end

#macro abaco(M, N, valor, PROB)

  #local AUX = 0;
union{
#while (AUX < M)
      object { fileira(N, valor[AUX], PROB) translate <0,0,AUX*3.5> }
      #local AUX = AUX+1;
  #end
  }
#end

#include "eixos.inc"

union {
        object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }

        object { abaco(4, 8 ,valor, 0.50) }
        object { abaco(3, 8 ,valor2, 0.25) translate <0, +10, 0>}

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.0, 3.00 >;
#declare raio_cena = 30.0;
#declare dir_camera = < sin(pi*clock), cos(pi*clock), 1.00 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)