// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_bola = 
  texture{
    pigment{ color rgb < 0.60, 0.70, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }
  
#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.90, 0.12, 0.20 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================

// Partes da cena: 

// orelha esquerda  

#declare caixa_fora =
  object {
    box{ <0,0,0>, <1,4,2> }

    translate < 0,0,0 >
    texture{ tx_bola }
  }

#declare caixa_dentro =
  object {
    box{ <0,0,0>, <1.2,3.8,1.8> }

    translate < 0,0,0 >
    texture{ tx_bola }
  }
  
#declare caixa = 
  difference { 
    object { caixa_fora translate < 0,0,0 > }
    object { caixa_dentro translate < -0.1,0.1,0.1 > }
  }

#declare pino = 
  cylinder{
    < 0, 0, 0 >,
    < 0, 0, 1 >,
    0.1
    texture{ tx_bola }
  }

#declare rosca = 
  cylinder{
    < 0, 0, 0 >,
    < 0, 0, 0.3 >,
    0.2
    texture{ tx_fosca }
  }

// ======================================================================

// Gerador de números aleatórios
#declare roleta = seed(417);

#macro bit_normal(valor)
  union {
    object{ pino translate < 0,0,0 > }
    object{ rosca translate < 0,0,0.7*valor > }
  }
#end

#macro bit(valor, defeito)
  #if (defeito)
    object{ pino }
  #else
    object{ bit_normal(valor) }
  #end
#end

#macro fileira(numbits, valor, prob) // n de bits, valor decimal, probabilidade
  #local r = int(valor);
  #local f = valor-r;
  #local k = 0;

  union {  
   #while (k < numbits)
      #local vb = mod(r,2);
      #local def = (rand(roleta) < prob);
      
      #if (vb=0)
        object { bit(f,def) translate < 0,-1*k,0 > }
        #local f = 0;
      #else
        object { bit(1-f,def) translate < 0,-1*k,0 > }
      #end
      
      #local r = int(r/2);
      #local k = k+1;
    #end
  }
  
#end

#declare valores = array[5];
#declare valores[0] = 1*clock + 0*(1-clock);
#declare valores[1] = 5*clock + 0*(1-clock);;
#declare valores[2] = 10*clock + 0*(1-clock);;
#declare valores[3] = 7*clock + 0*(1-clock);;
#declare valores[4] = 13*clock + 0*(1-clock);;

#macro abaco(m, n, valores, prob)
  #local i = 0;
  
  union {
    #while (i < m)
      object { fileira(n, valores[i], prob) translate< 0,0,-1.5*i > }
      
      #local i = i+1;
    #end
  }

#end

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ eixos(3.00) }
  
  object{ chao  translate < 0,0,-2 > texture{ tx_xadrez } }
  
  // CONTROLE POR AQUI O NUMERO DE LINHAS (M) E O NUMERO DE COLUNAS (N)
  // POIS AFETA A POSICAO NA TELA
  #local m = 4;
  #local n = 4;
  
  object{ abaco(m,n,valores,0.25) translate< 0,0,1.5*(m-1) > }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 3.00*clock >;
#declare raio_cena = 10;
#declare dir_camera = < 14.00, 0.00, 4.00 >;
#declare dist_camera = 10;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)