// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.4, 0.6, 0.8 > }

#declare tx_pele =
  texture{
    pigment{ color rgb < 0.70, 0.70, 0.70 > }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.5, 0.4, 0.8 >, color rgb < 1, 1, 1 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#include "textures.inc"

#declare chao =
  box{ <-25,-25,-1>, <+25,+25,0> }

#declare botao = union{
  box{<0.5,0.05,0.4>, <-0.5,-0.05,0> pigment{ color rgb < 0.20, 0.80, 0.20 > }}
  cylinder{<0,0,0>, <0,0,0.15>, 0.5  pigment{ color rgb < 0.90, 0.70, 0.30 > }}
}

#macro bit(valor, defeito, prob)
  #if(defeito>prob)
    object{botao rotate<0,0,90*valor>}
  #else
    union{
      object{botao rotate<0,0,0>}
      object{botao rotate<0,0,90>}
    }
  #end
#end

#macro linha(n, valor, prob)
  union{
    #local gnd = int(valor);
    #local diff = valor - gnd;
    #local top = gnd+1;
    #local i = 0;
    #while (i < n)
      object{bit(((1-diff)*mod(gnd,2)+diff*mod(top,2)), rand(semente), prob) translate<2*i-n+1, 0, 0>}
      #declare i = i + 1;
      #declare top = int(top/2);
      #declare gnd = int(gnd/2);
    #end
  }
#end

#macro abaco(m, n, valores, prob)
  union{
    #local i = 0;
    #while (i < m)
      object{linha(n, valores[i], prob) translate<0, 2*i-m+1, 0>}
      #declare i = i + 1;
    #end
    difference{
      box{<n+0.5, m+0.5, 0.5>, <-n-0.5, -m-0.5, -0.1> pigment{ color rgb < 0, 0, 1 > }}
      box{<n, m, 0.51>,        <-n, -m, 0>            pigment{ color rgb < 0, 0, 0 > }}
    }
  }
#end

#declare lista=array[15];
#declare lista[0]=11;
#declare lista[1]=(1-clock)*11 + clock*12;
#declare lista[2]=12;
#declare lista[3]=(1-clock)*12 + clock*11;
#declare lista[4]=(1-clock)*10 + clock*13;
#declare lista[5]=(1-clock)*7 + clock*8;
#declare lista[6]=(1-clock)*0 + clock*16;
#declare lista[7]=(1-clock)*0 + clock*31;;
#declare lista[8]=011;
#declare lista[9]=169;
#declare lista[10]=254;
#declare lista[11]=019;
#declare lista[12]=110;
#declare lista[13]=005;
#declare lista[14]=084;

#declare semente = seed(213);

#include "eixos.inc"

union{
  object{abaco(8, 5, lista, 0.2)}
  object{ chao texture{ tx_xadrez } rotate<90, 0, 0> translate<0, 8.5, 0>}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.01, 0.01 >;
#declare raio_cena = 15.0;
#declare dir_camera = < 0.00, 2-6*clock, 10.00 >;
#declare dist_camera = 30.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , -y, intens_luz)