//Pedro Feniman 083991

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico1 = 
  texture{
    pigment{ color rgb < 0.90, 0.85, 0.45 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_plastico2 = 
  texture{
    pigment{ color rgb < 0.70, 0.65, 0.75 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.10, 0.10 >, color rgb < 1, 1, 1 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare chao=
	box {
		<20 ,20, 0> 
		<-20, -20 , -2>  
		texture{ tx_xadrez }
	}	

#macro forma(ze)
	union{
		cylinder{
			< 0, 0, 0 >,
			< 0, 0, 1 >,
			0.2
			texture{ tx_plastico2 }
		}
		torus{
			0.35, 0.12 //raio maior e menor
			rotate -90*x  
			translate <0, 0, ze*0.6 + 0.25> 
			texture{ tx_fosca }
		}
	}
#end

#macro bit (valor, defeito)
	#if (defeito = 1)		
		object { forma(0.5) }
	#else 
		object { forma(valor) }
	#end
#end

#macro fileira(nbits, numero, prob)
	union{
		#local i = 0;
		#local nb = nbits;
		#local r = int(numero);
		#local vb = mod(r,2);
		#local f = numero - r;
		#while(nb != 0)
			#local def = ( rand(semente) < prob);
			#local vb = mod(r, 2);
			#if (vb = 0)
				object {bit(f, def) translate<0, -i*1, 0>}
				#local f = 0;
			#else
				object {bit(1-f, def) translate<0, -i*1, 0>}
			#end
			#local r = int(r/2);			
			#local nb = nb - 1;			
			#local i = i + 1;
			#local numero = int(numero/2);

		#end
	}
#end

#declare valores = array [7];
#declare valores [0] = (1-clock)*0 + clock*4;
#declare valores [1] = (1-clock)*4 + clock*8;
#declare valores [2] = (1-clock)*8 + clock*12;
#declare valores [3] = (1-clock)*25 + clock*30;
#declare valores [4] = (1-clock)*35 + clock*38;;
#declare valores [5] = (1-clock)*59 + clock*63;
#declare valores [6] = (1-clock)*47 + clock*50;

#declare valores1 = array [6];
#declare valores1 [0] = 3;
#declare valores1 [1] = 7;
#declare valores1 [2] = (1-clock)*9 + clock*15;
#declare valores1 [3] = (1-clock)*15 + clock*9;
#declare valores1 [4] = 19;
#declare valores1 [5] = 23;

#macro abaco(m, n, valores, prob)
	#local i = 0;
	union{	
		#while(i < m)
			object {fileira (n, valores[i], prob) translate <0, 0, i>}
			#local i = i+1;
			box {
				<-0.25 ,0.5-1*n, 0> 
				<0.25, 0.6 , 0.1>  
				texture{ tx_plastico1 }
				translate <0, 0, i>
			}	
		#end

		difference{
			box {
				< -0.25 ,0.5-1*n, 0> 
				<0.25, 0.6, 1*m>  
				texture{ tx_plastico1 }
			}
			box {
				< -1 ,0.6-1*n, 0.2> 
				<1, 0.5, 1*m>  
				texture{ tx_plastico1 }
			}
		}
	}
#end

#declare semente = seed(417);

union{
	object { abaco (7, 6, valores, 0.1) }
	object { abaco (6, 5, valores1, 0.05) translate <0, 7, 0> }
	object {chao}
}
#include "camlight.inc"
#declare centro_cena = < 0.00, 1.50, 3.5 >;
#declare raio_cena = 9.0;
#declare dir_camera = < (1-clock)*(40) + clock*50, (1-clock)*(-30) + clock*30, 10.00 >;
#declare dist_camera = 18.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)