// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }
#include "textures.inc"
#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare valores = array[10];
#declare valores[0] = (1-clock)*2.1 + clock*12.7;
#declare valores[1] = (1-clock)*12.7 + clock*11.8;
#declare valores[2] = (1-clock)*11.8 + clock*10.13;
#declare valores[3] = (1-clock)*10.13 + clock*5.15;
#declare valores[4] = (1-clock)*5.15 + clock*15.5;
#declare valores[5] = (1-clock)*15.5 + clock*13.10;
#declare valores[6] = (1-clock)*13.10 + clock*8.11;
#declare valores[7] = (1-clock)*8.11 + clock*7.12;
#declare valores[8] = (1-clock)*7.12 + clock*1.2;
#declare valores[9] = (1-clock)*1.2 + clock*2.7;

#macro bit (valor, defeito)
   union {
      cylinder {<0,0,0> <0,0,0.1> 0.3}

      #if (defeito=1)
         cylinder {<0,0,0> <0,0,0.3> 0.1}
      #else
         cylinder {<0,0,0> <0,-0.3 + 0.6*valor,0.3> 0.1}
      #end
   } texture {tx_espelho}
#end

#macro fileira (n, valor, prob)
   #declare roleta=seed(clock*234 + 213);
   #local i = 0;
   #local r = int(valor);
   #local f = valor - r;
   union {
   #while (i<n)
      #local vb = mod(r, 2);
      #if (vb=0)
         object{ bit( f, (rand(roleta) < prob) ) translate <i,0,0> }
         #local f=0;
      #else
         object{ bit( 1-f, (rand(roleta) < prob) ) translate <i,0,0> }
      #end
      #local r = int(r/2);
      #local i = i+1;
   #end
   }
#end

#macro abaco(m, n, vals, prob)
   #local i=0;
   union {
      object {difference {
         box {<-2,2,0.5> <n+1, -m-1,-0.5>}
         box {<-1,1,2> <n, -m,-2>}
      } texture {Cherry_Wood}
      }
      box {<-1,1,0> <n, -m,-0.3> texture {tx_vidro}}
      #while (i<m)
         object {fileira(n, vals[i], prob) translate <0,-i,0>}
         #local i = i+1;
      #end
   }

#end

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

union{

  union {
        object{abaco(10,6,valores, 0.2)}
  }
}

#include "camlight.inc"

#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 0.00, 4.00 - 2*clock, 3.00 >;
#declare dist_camera = 25.0;
#declare intens_luz = 1.25;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)