// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare marrom = 
  texture{
    pigment{ color rgb < 1, 0.51, 0.23 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare verde = 
  texture{
    pigment{ color rgb < 0, 1, 0 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare solo = 
  texture{
    pigment{ color rgb < 0, 0.8, 0 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
  
 #declare tx_vidro = 
	texture{
   pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
   finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
 }


// ======================================================================
// DESCRIÇÃO DA CENA 

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#declare phi = (sqrt(5)-1)/2;

#macro dodecaedro()
 intersection {
   plane { < 1, 0,  phi>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { < 1, 0, -phi>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <-1, 0,  phi>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <-1, 0, -phi>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { < phi,  1, 0>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <-phi,  1, 0>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { < phi, -1, 0>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <-phi, -1, 0>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <0,  phi,  1>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <0, -phi,  1>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <0,  phi, -1>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <0, -phi, -1>, 4 texture{ tx_vidro } interior{ ior 1.5 }}
 }
#end

#macro cubo()
intersection {
   plane { <  1,  0,  0>, 3.4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { < -1,  0,  0>, 3.4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <  0,  1,  0>, 3.4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <  0, -1,  0>, 3.4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <  0,  0,  1>, 3.4 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <  0,  0, -1>, 3.4 texture{ tx_vidro } interior{ ior 1.5 }}
}
#end


#macro octaedro()
 intersection {
   plane { <  1,  1,  1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <  1,  1, -1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <  1, -1,  1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { <  1, -1, -1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
	 plane { < -1,  1,  1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { < -1,  1, -1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { < -1, -1,  1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
   plane { < -1, -1, -1>, 3.8 texture{ tx_vidro } interior{ ior 1.5 }}
 }
#end


// ======================================================================
union {
	intersection {
		object{ octaedro() }
		object{ cubo() }
	}

	intersection {
		object{ octaedro() }
		object{ dodecaedro() }
		translate <15, 0, 0>
	} 
	
	object{ chao  translate < 0,0,-5 > texture { tx_xadrez } }
}


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 25.0;
#declare dir_camera = < 1, 1 - clock, 1 - clock >;
#declare dist_camera = 80.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)