// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_tronco = 
  texture{
    pigment{ color rgb < 0.65, 0.16, 0.16 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_chao = 
  texture{
    pigment{ color rgb < 0.15, 0.16, 0.16 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_branco = 
  texture{
    pigment{ color rgb < 0.8, 0.8, 0.8 > }
    finish{ diffuse 0.9 ambient 0.8 }
  }

#declare tx_vermelha = 
  texture{
    pigment{ color rgb < 0.89, 0.15, 0.13 > }
    finish{ diffuse 0.9 ambient 0.8 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.2, 0.3, 0.6 >, color rgb < 1, 1, 1 >}
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#include "eixos.inc"

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#local fi = (sqrt(5)-1)/2;

#macro cubo(r)
	union {
		intersection {
			plane{<0, 0, 1>, r}
			plane{<0, 0, -1>, r}
			plane{<0, 1, 0>, r}
			plane{<0, -1, 0>, r}
			plane{<1, 0, 0>, r}
			plane{<-1, 0, 0>, r}
			texture { tx_vidro }
			interior { ior 1.5 }
		}
	}
#end

#macro octaedro(r)
	union {
		intersection {
			plane{<1, 1, 1>, r}
			plane{<1, 1, -1>, r}
			plane{<1, -1, -1>, r}
			plane{<-1, -1, -1>, r}
			plane{<-1, -1, 1>, r}
			plane{<-1, 1, 1>, r}
			plane{<-1, 1, -1>, r}
			plane{<1, -1, 1>, r}
			texture { tx_vidro }
			interior { ior 1.5 }
		}
	}
#end

#macro dodecaedro(r)
	union {
		intersection {
 			plane{<1, 0, fi>, r}
 			plane{<1, 0, -fi>, r}
 			plane{<-1, 0, fi>, r}
 			plane{<-1, 0, -fi>, r}
 			plane{<fi, 1, 0>, r}
 			plane{<fi, -1, 0>, r}
 			plane{<-fi, 1, 0>, r}
 			plane{<-fi, -1, 0>, r}
 			plane{<0, fi, 1>, r}
			plane{<0, fi, -1>, r}
			plane{<0, -fi, 1>, r}
			plane{<0, -fi, -1>, r}
			texture { tx_vidro }
			interior { ior 1.5 }
		}
	}
#end

union{
	//object { eixos(10.0) }
	object{
		chao translate < 0,0,-5 > texture{ tx_xadrez }
	}
	intersection {
		object {
			octaedro(1) //texture { tx_vermelha }
		}
		object {
			dodecaedro(1.06) //texture { tx_branco }
		}
		translate <-2, 0, 0>
	}
	intersection {
		object {
			octaedro(1.15) //texture { tx_vermelha }
		}
		object {
			cubo(1) //texture { tx_branco }
		}
		translate <2, 0, 0>
	}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 7.0;
#declare dir_camera = < 0.00, 50.00, 20.00 >;
#declare dist_camera = 7.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)