// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS
background{ color rgb < 0.75, 0.60, 0.75 > }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.00, 0.02, 0.00 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }


// ======================================================================
// DESCRIÇÃO DA CENA 

#macro dodecaedro()
      #local fi = (sqrt(5)-1)/2;
      
      intersection{
        plane{ <1,0,fi>,  4}
        plane{ <1,0,-fi>, 4}
        plane{ <-1,0,fi>, 4}
        plane{ <-1,0,-fi>,4}
        plane{ <fi,1,0>,  4}
        plane{ <fi,-1,0>, 4}
        plane{ <-fi,1,0>, 4}
        plane{ <-fi,-1,0>,4}
        plane{ <0,fi,1>,  4}
        plane{ <0,fi,-1>, 4}
        plane{ <0,-fi,1>, 4}
        plane{ <0,-fi,-1>,4}
      }
#end

#macro octaedro()
	intersection{
        plane{ <1,1,1>,  3.8}
        plane{ <1,1,-1>, 3.8}
        plane{ <1,-1,1>, 3.8}
        plane{ <1,-1,-1>,3.8}
        plane{ <-1,1,1>, 3.8}
        plane{ <-1,1,-1>,3.8}
        plane{ <-1,-1,1>,3.8}
        plane{ <-1,-1,-1>,3.8}
      }
#end

#macro cubo()
	intersection{
        plane{ <1,0,0>, 3.5}
        plane{ <-1,0,0>,3.5}
        plane{ <0,1,0>, 3.5}
        plane{ <0,-1,0>,3.5}
        plane{ <0,0,1>, 3.5}
        plane{ <0,0,-1>,3.5}
      }
#end
   

#include "eixos.inc"

// Aqui está a cena, finalmente:
union{
  intersection{
    object{ dodecaedro()}
    object{ octaedro()}
    texture{ tx_vidro } interior{ior 1.5}  translate<-10,0,0>
  }

  intersection{
    object{ octaedro() }
    object{ cubo() }
    texture{ tx_vidro } interior{ior 1.5}  translate<10,0,0>
  }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 40.0;
#declare dir_camera = < 0.00, 3.00, 0.00 >;
#declare dist_camera = 10.0;
#declare intens_luz = 2.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)