// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_verde = 
  texture{
    pigment{ color rgb < 0, 1, 0 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================


#include "eixos.inc"

#declare phi = (sqrt(5)-1)/2;
#declare dist = 2;

#macro plano(a, b, c)
    object{ 
		plane {
			<a, b, c>, dist
			interior { ior 1.5 } 
		} 
	}
#end

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#macro dodecaedro()
  intersection{

	plano(1,0,phi)
	plano(1,0,-phi)
	plano(-1,0,phi)
	plano(-1,0,-phi)

	plano(phi,1,0)
	plano(phi,-1,0)
	plano(-phi,1,0)
	plano(-phi,-1,0)

	plano(0,phi,1)
	plano(0,phi,-1)
	plano(0,-phi,1)
	plano(0,-phi,-1)

	bounded_by { sphere { <0,0,0> , 7 } }
  }
#end

#macro octaedro()
  intersection{

	plano(1,1,1)
	plano(1,1,-1)
	plano(1,-1,1)
	plano(1,-1,-1)
	plano(-1,1,1)
	plano(-1,1,-1)
	plano(-1,-1,1)
	plano(-1,-1,-1)


	bounded_by { sphere { <0,0,0> , 7 } }
  }
#end

#macro cubo()
  intersection{

	plano(1,0,0)
	plano(0,1,0)
	plano(0,0,1)

	plano(-1,0,0)
	plano(0,-1,0)
	plano(0,0,-1)
	

	bounded_by { sphere { <0,0,0> , 5 } }
  }
#end

#macro icosaedro()
  intersection{

	
	object { dodecaedro()  }
	object { octaedro() scale 0.94  }

	

	bounded_by { sphere { <0,0,0> , 5 } }
  }
#end

#macro cubo_octaedro()
  intersection{

	
	object { cubo() scale 0.865  }
	object { octaedro()   }

	

	bounded_by { sphere { <0,0,0> , 5 } }
  }
#end




union{
	//object { dodecaedro() translate < 0,0,0 > texture { tx_vidro } 	}
	//object { octaedro() translate < 0,-6,0 > texture { tx_vidro } 	}
	//object { cubo() translate < 0,6,0 > texture { tx_vidro } 	}
	object { icosaedro() translate < 0,3,0 > texture { tx_vidro } 	}
	object { cubo_octaedro() translate < 0,-3,0 > texture { tx_vidro } 	}
	
}
object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 1.00, 0.00, 0.40 >;
#declare dist_camera = 15.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)