// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
  
#declare bola =
  sphere{
            < 0.00, 0.00, 0.0 >, 1
            texture{ tx_plastico}
  }
    


#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> texture{ tx_xadrez }}
  
#declare A= (sqrt(5) - 1)/2;

#declare dode =
    intersection {
        plane { <1, 0, A>, 1 }
        plane { <-1, 0, A>, 1 }
        plane { <1, 0, -A>, 1 }
        plane { <-1, 0, -A>, 1 }
        
        plane { <A, 1, 0>, 1 }
        plane { <A, -1, 0>, 1 }
        plane { <-A, 1, 0>, 1 }
        plane { <-A, -1, 0>, 1 }
        
        plane { <0, A, 1>, 1 }
        plane { <0, A, -1>, 1 }
        plane { <0, -A, 1>, 1 }
        plane { <0, -A, -1>, 1 }
    }
    
#declare B = 0.95;
    
#declare octa =
    intersection {
        plane{ < 1 , 1 , 1 >, B}
        plane{ < 1 , 1, -1 >, B}
        plane{ < 1 , -1 , 1 >, B}
        plane{ < 1 , -1, -1 >, B}
        plane{ < -1 , 1 , 1 >, B}
        plane{ < -1 , -1 , 1 >, B}
        plane{ < -1 , -1 , -1 >, B}
        plane{ < -1 , 1 , -1 >, B}
    }
    
#declare C = 0.81;    
    
#declare cubo = 
    intersection {
        plane{ < 1 ,0 ,0 >, C }    
        plane{ < -1 ,0 ,0 >, C }
        
        plane{ < 0 ,1 ,0 >, C }
        plane{ < 0 ,-1 ,0 >, C }
        
        plane{ < 0 ,0 ,1 >, C }
        plane{ < 0 ,0 ,-1 >, C }    
    }   
    
#declare poligonox =
    intersection {
        object{cubo}
        object{octa}
    }
    
#declare icosa =
    intersection {
        object{dode}
        object{octa}
    }

// ======================================================================
// DESCRIÇÃO DA CENA 

#include "eixos.inc"

union {
    //object{ eixos(3.00) }
    object{chao}


    //object{ dode texture{ tx_plastico} interior{ior 1.5} translate<0,0,3>}
    //object{ octa texture{ tx_vidro} interior{ior 1.5} translate<0,0,3>}
    
    object{icosa texture{ tx_vidro} interior{ior 1.5} translate<0,0,3> }
    
    object{poligonox texture{ tx_vidro} interior{ior 1.5} translate<0,3,3> }
    
}   

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)