// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#declare aurea = (sqrt(5)+1)/2;

#include "eixos.inc"

// Aqui está a cena, finalmente:


#macro dodecaedro(tam)
union{
  //object{ eixos(3.00) }
  intersection {
    plane{<1,0,aurea>,tam}  
    plane{<1,0,-aurea>,tam}
    plane{<-1,0,aurea>,tam}
    plane{<-1,0,-aurea>,tam}
    plane{<aurea,1,0>,tam}
    plane{<-aurea,1,0>,tam}
    plane{<aurea,-1,0>,tam}
    plane{<-aurea,-1,0>,tam}
    plane{<0,aurea,1>,tam}
    plane{<0,-aurea,1>,tam}
    plane{<0,aurea,-1>,tam}
    plane{<0,-aurea,-1>,tam}
  }
}
#end

#macro octaedro(tam)
union{
  object{ eixos(3.00) }
  intersection {
    plane{<1,1,1>,tam}  
    plane{<1,1,-1>,tam}  
    plane{<1,-1,1>,tam}  
    plane{<-1,1,1>,tam}
    plane{<1,-1,-1>,tam}
    plane{<-1,1,-1>,tam}
    plane{<-1,-1,1>,tam}
    plane{<-1,-1,-1>,tam}
  }
}
#end

#macro icosaedro (tam)
union{
  object{ eixos(3.00) }
  intersection {
    object{dodecaedro(tam*1.09)}
    object{octaedro(tam)}
  }
}
#end

#macro cubo(tam)
union{
  object{ eixos(3.00) }
  intersection {
    plane{<0,0,1>,tam}  
    plane{<0,0,-1>,tam}  
    plane{<0,-1,0>,tam}  
    plane{<0,1,0>,tam}
    plane{<1,0,0>,tam}
    plane{<-1,0,0>,tam}
  }
}
#end

#macro catorze (tam)
union{
  object{ eixos(3.00) }
  intersection {
    object{octaedro(tam*1.15)}
    object{cubo(tam)}
  }
}
#end


union {
  //object{ dodecaedro(1) texture{tx_vidro} interior{ ior 1.5} }
  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
  //object{ octaedro(1) texture{tx_vidro} interior{ ior 1.5} }
  //object{ cubo(1) texture{tx_vidro} interior{ ior 1.5} }
  object{ icosaedro(1) texture{tx_vidro} interior{ ior 1.5} translate<2,0,0> }
  object{ catorze(1) texture{tx_vidro} interior{ ior 1.5} translate<-2,0,0>}
}


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 0.00, 2.00, 6.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)