// CORES E TEXTURAS

background{ color rgb < 0, 0, 0 > }

#include "eixos.inc"
#include "textures.inc"

//texturas:
#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_vidro_verde = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 0.10 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_vidro_vermelho = 
  texture{
    pigment{ color rgb < 0.80, 0.10, 0.10 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

//valores:
#declare phi = (sqrt(5)+1)/2;
#declare distancia = 3;

//partes da cena:
#macro dodecaedro ()
	intersection{
		plane{ <1,0,phi> , distancia }
		plane{ <1,0,-phi> , distancia }
		plane{ <-1,0,phi> , distancia }
		plane{ <-1,0,-phi> , distancia }
		plane{ <phi,1,0> , distancia }
		plane{ <phi,-1,0> , distancia }
		plane{ <-phi,1,0> , distancia }
		plane{ <-phi,-1,0> , distancia }
		plane{ <0,phi,1> , distancia }
		plane{ <0,phi,-1> , distancia }
		plane{ <0,-phi,1> , distancia }
		plane{ <0,-phi,-1> , distancia }
	}
#end

#macro octaedro ()
	intersection{
		plane{ <1,1,1>, distancia }
		plane{ <1,1,-1>, distancia }
		plane{ <1,-1,1>, distancia }
		plane{ <-1,1,1>, distancia }
		plane{ <1,-1,-1>, distancia }
		plane{ <-1,1,-1>, distancia }
		plane{ <-1,-1,1>, distancia }
		plane{ <-1,-1,-1>, distancia }
	}
#end

#macro icosaedro ()
	intersection{
		object{ dodecaedro() scale 1.065 }
		object{ octaedro()  }
	}
#end

#macro cubo ()
	intersection{
		plane{ <1,0,0>, distancia }
		plane{ <0,1,0>, distancia }
		plane{ <0,0,1>, distancia }
		plane{ <-1,0,0>, distancia }
		plane{ <0,-1,0>, distancia }
		plane{ <0,0,-1>, distancia }
	}
#end

#macro cubo_octaedro ()
	intersection{
		object{ cubo() scale 0.87 }
		object{ octaedro()  }
	}
#end

//cena:
union{
	object { eixos(10.0) } 

	plane{ <0,0,1>, -20 texture{tx_xadrez} }
	//object { dodecaedro() }
	//object { octaedro() }
	object{ icosaedro () texture{ tx_vidro_verde } interior{ ior 1.15 } translate 4*y }
	object{ cubo_octaedro () texture{ tx_vidro_vermelho } interior{ ior 1.15 } translate -4*y }

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 11.0;
#declare dir_camera = < 10.00, 2, 10 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)