/// Exemplo de arquivo de descricao de cena para POV-ray

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }


#declare tx_preta = 
  texture{
    pigment{ color rgb < 0.20, 0.20, 0.20 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 1, 0.24, 0.3 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_rosquinha = 
 texture{
   pigment{ color rgb < 0.566, 0.276, 0.076 > }
   finish{ diffuse 0.9 ambient 0.1 }
 }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }
#declare phi = (sqrt(5)-1)/2;
#declare distancia = 1;
// ======================================================================
// DESCRIÇÃO DA CENA 
#declare chao = 
  box{ <-70,-70,-6>, <+70,+70,-5> }
#macro dodecaedro()
 object {
  intersection{
    plane {<0,phi,1>, distancia}
    plane {<0,phi,-1>, distancia}
    plane {<0,-phi,1>, distancia}
    plane {<0,-phi,-1>, distancia}
    plane {<1,0,phi>, distancia}
    plane {<1,0,-phi>, distancia}
    plane {<-1,0,phi>, distancia}
    plane {<-1,0,-phi>, distancia}
    plane {<-phi,1,0>, distancia}
    plane {<phi,1,0>, distancia}
    plane {<-phi,-1,0>, distancia}
    plane {<phi,-1,0>, distancia}
  } bounded_by {sphere{<0,0,0> , 2}}
}
#end

#macro octaedro()
 object {
  intersection{
    plane {<1,1,1>, distancia}
    plane {<1,1,-1>, distancia}
    plane {<1,-1,1>, distancia}
    plane {<1,-1,-1>, distancia}
    plane {<-1,1,1>, distancia}
    plane {<-1,1,-1>, distancia}
    plane {<-1,-1,1>, distancia}
    plane {<-1,-1,-1>, distancia}
  } bounded_by {sphere{<0,0,0> , 2}}
}
#end

#macro cubo()
 object {
  intersection{
    plane {<1,0,0>, distancia}
    plane {<0,1,0>, distancia}
    plane {<0,0,1>, distancia}
    plane {<-1,0,0>, distancia}
    plane {<0,-1,0>, distancia}
    plane {<0,0,-1>, distancia}
  } bounded_by {sphere{<0,0,0> , 2}}
}
#end

#include "eixos.inc"

object{ chao texture{ tx_xadrez }  }
object{
  intersection{
  object{dodecaedro() scale 1.07 texture{ tx_vidro } interior {ior 1.2} }
  object{octaedro() texture{ tx_vidro } interior {ior 1.2} }
  }
  translate<-4,0,0>
}
object{
  intersection{
  object{cubo() scale 0.85 texture{ tx_vidro } interior {ior 1.2} }
  object{octaedro() texture{ tx_vidro } interior {ior 1.2} }
  } translate<+4,0,0>
}
//object{dodecaedro() texture{ tx_vidro } interior {ior 1.2} }
//object{cubo() texture{ tx_vidro } interior {ior 1.2} translate<0,+4,0>}
//object{octaedro() texture{ tx_vidro } interior {ior 1.2} translate<0,-4,0>}
//object{cubo() texture{ tx_vidro } interior {ior 1.2} }

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dir_cameraFinal = < 7, 14, 4 >;
#declare valorMedCamera = (1-clock)*dir_camera + clock*dir_cameraFinal;
#declare dist_camera = 70.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, valorMedCamera, dist_camera , z, intens_luz)