// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_vidro =
 texture{
   pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
   finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
 }

#declare tx_blueglass = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > filter 0.70}
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_yellowglass =
  texture{
    pigment{ color rgb < 1.00, 1.00, 0.00 > filter 0.70}
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_greenglass =
  texture{
    pigment{ color rgb < 0.00, 1.00, 0.00 > filter 0.70}
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// DESCRIÇÃO DA CENA 

// Partes da cena:

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#macro dodecaedro(posicao)
  #local numAureo = (sqrt(5) + 1)/2;
  
  object{
    intersection{
      plane{<1,0,numAureo>,1}
      plane{<1,0,-numAureo>,1}
      plane{<-1,0,numAureo>,1}
      plane{<-1,0,-numAureo>,1}
      plane{<numAureo,1,0>,1}
      plane{<numAureo,-1,0>,1}
      plane{<-numAureo,1,0>,1}
      plane{<-numAureo,-1,01>,1}
      plane{<0,numAureo,1>,1}
      plane{<0,numAureo,-1>,1}
      plane{<0,-numAureo,1>,1}
      plane{<0,-numAureo,-1>,1}
    } 
    translate < 0, posicao, 0 >
  }
#end

#macro octaedro(posicao)
  object{
    intersection{
      plane{<1,1,1>,1}      
      plane{<1,1,-1>,1}
      plane{<1,-1,1>,1}
      plane{<1,-1,-1>,1}
      plane{<-1,1,1>,1}
      plane{<-1,1,-1>,1}
      plane{<-1,-1,1>,1}
      plane{<-1,-1,-1>,1}
    } 
    translate < 0, posicao, 0 >
  }
#end

#macro icosaedro(posicao)
  #local numAureo = (sqrt(5) + 1)/2;
  #local r1 = 1;
  #local r2 = 1.06;
  
  object{
    intersection{
      object{
	intersection{
	  plane{<1,1,1>,r1}      
	  plane{<1,1,-1>,r1}
	  plane{<1,-1,1>,r1}
	  plane{<1,-1,-1>,r1}
	  plane{<-1,1,1>,r1}
	  plane{<-1,1,-1>,r1}
	  plane{<-1,-1,1>,r1}
	  plane{<-1,-1,-1>,r1}
	} texture{ tx_vidro }
      }
      object{
	intersection{
	  plane{<1,0,numAureo>,r2}
	  plane{<1,0,-numAureo>,r2}
	  plane{<-1,0,numAureo>,r2}
	  plane{<-1,0,-numAureo>,r2}
	  plane{<numAureo,1,0>, r2}
	  plane{<numAureo,-1,0>, r2}
	  plane{<-numAureo,1,0>, r2}
	  plane{<-numAureo,-1,0>,r2}
	  plane{<0,numAureo,1>, r2}
	  plane{<0,numAureo,-1>, r2}
	  plane{<0,-numAureo,1>, r2}
	  plane{<0,-numAureo,-1>, r2}
	} texture{ tx_blueglass }
      }
    }
    translate < 0, posicao, 0 >
  }
#end

#macro cuboctaedro(posicao)
  #local numAureo = (sqrt(5) + 1)/2;
  #local r1 = 1;
  #local r2 = 1;
  
  object{
    intersection{
      object{
	intersection{
	  plane{<1,0,0>,r1}      
	  plane{<0,1,0>,r1}
	  plane{<0,0,1>,r1}
	  plane{<-1,0,0>,r1}      
	  plane{<0,-1,0>,r1}
	  plane{<0,0,-1>,r1}
	} texture{ tx_greenglass }
      }
      object{
	intersection{
	  plane{<1,1,1>,r2}      
	  plane{<1,1,-1>,r2}
	  plane{<1,-1,1>,r2}
	  plane{<1,-1,-1>,r2}
	  plane{<-1,1,1>,r2}
	  plane{<-1,1,-1>,r2}
	  plane{<-1,-1,1>,r2}
	  plane{<-1,-1,-1>,r2}
	} texture{ tx_yellowglass }
      }
    }
    translate < 0, posicao, 0 >
  }
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:
 
union{
//  object{ eixos(3.00) }
   
  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
  
//  object{ dodecaedro(-6) texture{tx_vidro} interior { ior 1.2 }}
//  object{ octaedro(-2) texture{tx_blueglass} interior { ior 1.2 }}
  object{ icosaedro(-2) interior { ior 1.2 }}
  object{ cuboctaedro(2) interior { ior 1.2 }}  
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 0.00, 8.00 >;
#declare dist_camera = 8.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)