// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }
#include "textures.inc"
#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.75, 0.75, 0.5 > filter 0.90 }
    finish{ diffuse 0 reflection 0.4 ambient 0.02 specular 0.25 roughness 0.1 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.80, 0.1, 0.10 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare phi = (sqrt(5) - 1)/2;

#declare cubo = object {
   intersection {
        plane {<1,0,0> 2}
        plane {<0,1,0> 2}
        plane {<0,0,1> 2}
        
        plane {<-1,0,0> 2}
        plane {<0,-1,0> 2}
        plane {<0,0,-1> 2}
                 
  }
   texture {tx_vidro} interior {ior 1.5} bounded_by { sphere{<0,0,0>, 5 }}  
  }
  
#declare dodecaedro = object {
   intersection {
        plane {<1,0,phi> 2}
        plane {<phi,1,0> 2}
        plane {<0,phi,1> 2}
        
        plane {<-1,0,phi> 2}
        plane {<phi,-1,0> 2}
        plane {<0,phi,-1> 2}
        
        plane {<1,0,-phi> 2}
        plane {<-phi,1,0> 2}
        plane {<0,-phi,1> 2}
        
        plane {<-1,0,-phi> 2}
        plane {<-phi,-1,0> 2}
        plane {<0,-phi,-1> 2}
                 
  } texture {tx_vidro} interior {ior 1.5} bounded_by { sphere{<0,0,0>, 5 }} 
  }
  
#declare octaedro = object {
   intersection {
      plane {<1,1,1> 2}
      plane {<1,1,-1> 2}
      plane {<1,-1,1> 2} 
      plane {<1,-1,-1> 2}                
      plane {<-1,1,1> 2}
      plane {<-1,1,-1> 2}
      plane {<-1,-1,1> 2}
      plane {<-1,-1,-1> 2}     
                  
   } texture {tx_vidro} interior {ior 1.5} bounded_by { sphere{<0,0,0>, 5 }}
}

#declare semirregular = object {
   intersection {
      intersection {
         plane {<1,1,1> 2}
         plane {<1,1,-1> 2}
         plane {<1,-1,1> 2} 
         plane {<1,-1,-1> 2}                
         plane {<-1,1,1> 2}
         plane {<-1,1,-1> 2}
         plane {<-1,-1,1> 2}
         plane {<-1,-1,-1> 2}     
                  
      }
      intersection {
           plane {<1,0,0> 2}
           plane {<0,1,0> 2}
           plane {<0,0,1> 2}
           
           plane {<-1,0,0> 2}
           plane {<0,-1,0> 2}
           plane {<0,0,-1> 2}
                    
     }
        
 } texture {tx_vidro} interior {ior 1.5} bounded_by { sphere{<0,0,0>, 5 }}
}


#declare icosaedro = object {
intersection {
      intersection {
         plane {<1,1,1> 2}
         plane {<1,1,-1> 2}
         plane {<1,-1,1> 2} 
         plane {<1,-1,-1> 2}                
         plane {<-1,1,1> 2}
         plane {<-1,1,-1> 2}
         plane {<-1,-1,1> 2}
         plane {<-1,-1,-1> 2}     
                  
      }
      intersection {
        plane {<1,0,phi> 2}
        plane {<phi,1,0> 2}
        plane {<0,phi,1> 2}
        
        plane {<-1,0,phi> 2}
        plane {<phi,-1,0> 2}
        plane {<0,phi,-1> 2}
        
        plane {<1,0,-phi> 2}
        plane {<-phi,1,0> 2}
        plane {<0,-phi,1> 2}
        
        plane {<-1,0,-phi> 2}
        plane {<-phi,-1,0> 2}
        plane {<0,-phi,-1> 2}
                    
     }
        
 } texture {tx_vidro} interior {ior 1.5} bounded_by { sphere{<0,0,0>, 5 }}
}

#include "eixos.inc"

// Aqui está a cena, finalmente:

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

union{     
  object{ icosaedro translate <0,-10,4> }
  object{ cubo   translate <0,10,4> }
  object{ semirregular translate <0,0,3> }
  
  object{ chao  translate < 0,0, 0 > texture{ tx_xadrez } } 
}



	 
#include "camlight.inc"

#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 18.0;
#declare dir_camera = < 5.00, 0.00, 1.00 >;
#declare dist_camera = 25.0;
#declare intens_luz = 1.25;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)