//Caixa de Surpresas

// ======================================================================
// CORES E TEXTURAS

#include "colors.inc"
#include "stones.inc"

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }
  
#declare tx_color = 
  texture{
    pigment{ color rgb < 2.00, 0.40, 0.20 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }


// ======================================================================
// DESCRICAO DA CENA 

#include "eixos.inc"

#declare chao = box{ <-20,-20,-1>, <+20,+20,0> }

#declare cubo = object {
   intersection{
      plane {<1, 0, 0>, 1}
      plane {<-1, 0, 0>, 1}
      plane {<0, 1, 0>, 1}
      plane {<0, -1, 0>, 1}
      plane {<0, 0, 1>, 1}
      plane {<0, 0, -1>, 1}
   }
   bounded_by{sphere{<0,0,0>, 10}}
   texture {tx_vidro}
   interior {ior 1.5}
}

#declare dodecaedro = object {
   intersection{
      plane {<1, 0, 1.4>, 1}
      plane {<-1, 0, 1.4>, 1}
      plane {<1, 0, -1.4>, 1}
      plane {<-1, 0, -1.4>, 1}
      plane {<1.4, 1, 0>, 1}
      plane {<1.4, -1, 0>, 1}
      plane {<-1.4, 1, 0>, 1}
      plane {<-1.4, -1, 0>, 1}
      plane {<0, 1.4, 1>, 1}
      plane {<0, 1.4, -1>, 1}
      plane {<0, -1.4, 1>, 1}
      plane {<0, -1.4, -1>, 1}
   }
   bounded_by{sphere{<0,0,0>, 10}}
   texture {tx_vidro}
   interior {ior 1.5}
}

#declare octaedro = object {
   intersection{
      plane {<1, 1, 1>, 1}
      plane {<1, 1, -1>, 1}
      plane {<1, -1, 1>, 1}
      plane {<1, -1, -1>, 1}
      plane {<-1, 1, 1>, 1}
      plane {<-1, 1, -1>, 1}
      plane {<-1, -1, 1>, 1}
      plane {<-1, -1, -1>, 1}
   }
   bounded_by{sphere{<0,0,0>, 10}}
   texture {tx_vidro}
   interior {ior 1.5}
}

#declare cuboctaedro = object {
   intersection{
      object{cubo}
      object{octaedro scale <1.15, 1.15, 1.15>}
   }
}

#declare icosaedro = object {
   intersection{
      object{octaedro}
      object{dodecaedro scale <1.1, 1.1, 1.1>}
   }
   texture {tx_vidro}
   interior {ior 1.5}
}

object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
object{cuboctaedro translate < 0,-3,2 >}
object{icosaedro translate < 0,3,2 >}

object {eixos(3.00)}



#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 7.0;
#declare dir_camera = < 2, -2, 2.00 >;
#declare dist_camera = 300.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)