// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_verde = 
  texture{
    pigment{ color rgb < 0, 1, 0 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare phi = (sqrt(5) - 1)/2;

#declare quantos_valores = 2;
#declare valores = array[quantos_valores];
#declare valores[0] = 31;
#declare valores[1] = 0;

#declare valores2 = array[quantos_valores];
#declare valores2[0] = 31;
#declare valores2[1] = 0;

#declare roleta = seed(417); // gerador aleatorio

#macro interpola (f0, v0, f1, v1, f)
    #local ss = (f-f0)/(f1-f0);
    #local rr = 1 - ss;
    (rr * v0 + ss * v1);
#end

#macro interpola_nova(t0,v0,v1,v2,v3,t1,tt)

  #local v01	= interpola(t0, v0,   t1, v1,  tt);
  #local v12	= interpola(t0, v1,   t1, v2,  tt);
  #local v23	= interpola(t0, v2,   t1, v3,  tt);
  #local v012	= interpola(t0, v01,  t1, v12, tt);
  #local v123	= interpola(t0, v12,  t1, v23, tt);
  #local v0123	= interpola(t0, v012, t1, v123,tt);

  v0123

#end

#macro ponto(xx)

  sphere {
      <0, 0, xx>, // center
      0.2 	 // radius
      texture{ tx_fosca }
  }

#end

#macro grafico(x0, y0, y1, y2, y3, x3, N)

  #local espaco = (x3 - x0)/N;
  #local x_t = x0;

  union {
    
    #while(x_t < x3)
      
      #local y_t = interpola_nova(x0, y0, y1, y2, y3, x3, x_t);
      //#debug concat(str(x_t, 8, 6), " ", str(y_t, 8, 6)
      object{ ponto(x_t) translate y_t}
      //object{ ponto(x_t) translate <0, x_t, y_t>}
      #local x_t = x_t + espaco;

    #end
  }
#end

#include "eixos.inc"

union{

  object{ eixos(5.00) }
  //object{ ponto() }

  #local y0a = <5, 3>;
  #local y0b = <2, 2>;
  #local y0c = <3, 3>;

  #local y1b = <7, 4>;
  #local y1c = <3, 1>;
  
  #local y2b = <8, 4>;
  #local y2c = <1, 2>;
  
  #local y3b = <6, 4>;
  #local y3c = <6, 2>;
  #local y3d = <7, 1>;

  #local y0d = (y0c + y1b)/2;
  #local y1d = (y1c + y2b)/2;
  #local y2d = (y2c + y3b)/2;
  #local y1a = y0d;
  #local y2a = y1d;
  #local y3a = y2d;

  object{ grafico(0, y0a, y0b, y0c, y0d, 2, 20) }
  object{ grafico(2, y1a, y1b, y1c, y1d, 4, 20) }
  object{ grafico(4, y2a, y2b, y2c, y2d, 6, 20) }
  object{ grafico(6, y3a, y3b, y3c, y3d, 8, 20) }
  
}

#include "camlight.inc"
#declare centro_cena = < 1.00, 0.00, 0.00 >;
#declare raio_cena = 20.0;
//#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)