// CORES E TEXTURAS

background{ color rgb < 0, 0, 0 > }

#include "eixos.inc"
#include "textures.inc"
#include "retalho.inc"

//texturas:
#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_vidro_verde = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 0.10 > filter 0.90 }
    finish{ diffuse 1 reflection 0.1 ambient 0.02 specular 0.25 roughness 0.1 }
  }

#declare tx_vidro_vermelho = 
  texture{
    pigment{ color rgb < 0.80, 0.10, 0.10 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.7 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

//valores:
#declare grafico_ponto_raio = 0.05;

//partes da cena:


#macro interpola(t0,v0,t1,v1,tt)
	#local ss = (tt-t0)/(t1-t0);
	#local rr = 1-ss;
	(rr*v0+ss*v1)
#end 

#macro interpola4(t0,v0,v1,v2,v3,t3,tt)
	#local v01 = interpola(t0,v0,t3,v1,tt);
	#local v12 = interpola(t0,v1,t3,v2,tt);
	#local v23 = interpola(t0,v2,t3,v3,tt);
	#local v012 = interpola(t0,v01,t3,v12,tt);
	#local v123 = interpola(t0,v12,t3,v23,tt);
	#local v0123 = interpola(t0,v012,t3,v123,tt);
	(v0123)
#end

#macro grafico_ponto (tt,vv)
	sphere{ 
		vv , 
		grafico_ponto_raio 
		texture{ tx_fosca }
	}
#end

#macro grafico_ponto2 (tt,vv)
	sphere{ 
		vv , 
		grafico_ponto_raio*5 
		texture{ tx_fosca }
	}
#end

#macro grafico(t0,v0,v1,v2,v3,t3,n)
	#local delta = (t3-t0)/(n-1);
	#local tt = t0;
	#while(tt<=t3)
		#local vv = interpola4(t0,v0,v1,v2,v3,t3,tt);
		grafico_ponto(tt,vv)
		#local tt = tt + delta;
	#end
#end

#macro grafico4(t0a,v0a,v1a,v2a,v1b,v2b,v1c,v2c,v1d,v2d,t3d,v3d,n)
	union{
	#local t3a = t0a+1*(t3d-t0a)/4;
	#local v3a = (v2a+v1b)/2;
	grafico(t0a,v0a,v1a,v2a,v3a,t3a,n/4)
	#local t3b = t0a+2*(t3d-t0a)/4;
	#local v3b = (v2b+v1c)/2;
	grafico(t3a,v3a,v1b,v2b,v3b,t3b,n/4)
	#local t3c = t0a+3*(t3d-t0a)/4;
	#local v3c = (v2c+v1d)/2;
	grafico(t3b,v3b,v1c,v2c,v3c,t3c,n/4)
	grafico(t3c,v3c,v1d,v2d,v3d,t3d,n/4)}
#end

#macro retalho2(p11,p12,p13,p14,
		p21,p22,p23,p24,
		p31,p32,p33,p34,
		q21,q22,q23,q24,
		q31,q32,q33,q34,
		q41,q42,q43,q44,
		rad,txg,txr)
	#local p41 = (p31+q21)/2;
	#local p42 = (p32+q22)/2;
	#local p43 = (p33+q23)/2;
	#local p44 = (p34+q24)/2;
union{
	retalho (p11,p12,p13,p14,p21,p22,p23,p24,p31,p32,p33,p34,p41,p42,p43,p44, rad,txg,txr)
	retalho (p41,p42,p43,p44,q21,q22,q23,q24,q31,q32,q33,q34,q41,q42,q43,q44, rad,txg,txr)
}
#end

//cena:
union{

	object{
		grafico4(0, <0,0,2>, <0,0,5>, <-3,4,0>,
		    <-2,-1,1>, <3,5,-2>,
		    <3,3,-5>, <0,-4,3>,
		    <2,4,-3>, <0,0,1>, 1, <0,0,2>,
		    1000)
		translate <3,-4,3>
	}
	//grafico_ponto2(0,<0,0,5>)
	//grafico_ponto2(1,<-3,4,0>)
	//grafico_ponto2(2,<-3,4,0>)
	//grafico_ponto2(3,<3,5,-2>)
	//grafico_ponto2(4,<3,5,-2>)
	//grafico_ponto2(5,<0,-4,3>)
	//grafico_ponto2(6,<0,-4,3>)
	//grafico_ponto2(7,<0,0,5>)*/
	//plane{ <0,0,1>, 0  interior{ ior 1.15 } }
	//plane{ <1,0,0>, 0  interior{ ior 1.15 } }
/*	retalho(  <0,0,5>, <0,1,0>, <0,3,0>, <0,5,2>,
		  <1,0,3>, <1,1,0>, <2,3,1>, <2,5,0>,
		  <4,0,1>, <3,1,0>, <3,4,-1>, <3,5,0>,
		  <5,0,0>, <5,2,-1>, <5,3,0>, <5,5,-2>,
		  0.03, tx_fosca, tx_vidro_verde )*/
	object{
	      retalho2( <0,0,5>, <0,1,0>, <0,3,0>, <0,5,2>,
		  <1,0,3>, <1,1,0>, <2,3,1>, <2,5,0>,
		  <4,0,1>, <3,1,0>, <3,4,-1>, <3,5,0>,
		  <6,0,0>, <6,2,-1>, <6,3,0>, <6,5,-2>,
		  <7,0,0>, <7,2,-1>, <7,3,-1>, <7,5,-1>,
		  <8,0,-1>, <8,2,-1>, <8,3,0>, <8,5,0>,
		  0.03, tx_fosca, tx_vidro_verde )
	      translate -1*z
	}
	object { eixos(10.0) }
}

#include "camlight.inc"
#declare centro_cena = < 3.00, 2.00, 0.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 10.00, 4, 3 >;
#declare dist_camera = 10.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)