// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.70, 0.70, 0.50 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 0.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 1.250;

// Partes da cena:
  
#declare cabeca = 
  sphere{ 
    < 0,0,0 >, 
    0.70*raio 
    texture{ tx_espelho }
  }

#declare pescoco = 
  cylinder {
    < 0, 0, -0.5*raio >,
    < 0, 0, 0.5*raio >,
    0.3*raio
    texture{ tx_fosca }
  }

#declare corpo =
  box { 
    < -1 * raio, -2*raio, -1*raio >,
    < raio, 2*raio, raio >
    texture{ tx_fosca }
  }

#declare peh =
  box { 
    < -0.8*raio, -0.4*raio, -0.4*raio >,
    < 0.8*raio, 0.4*raio, 0.4*raio >
    texture{ tx_fosca }
  }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

  object{ eixos(3.00) }
  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
  
  union{
    object{ corpo translate < 0, 0, -0.8*raio > }
    object{ peh translate < 0, -0.8*raio, -2*raio > }
    object{ peh translate < 0, 0.8*raio, -2*raio  > }
    union {
      object{ pescoco }
      object{ cabeca translate < 0, 0, 1.1*raio > }
      translate < 0, -0.8*raio, 0.7*raio >
    }
    union {
      object{ pescoco }
      object{ cabeca translate < 0, 0, 1.1*raio > }
      translate < 0, 0.8*raio, 0.7*raio >
    }
    translate < -4*raio, 2*raio, 2*raio >  
  }


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 13.0;
//#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)