// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_chif =  
  texture{
    pigment{ color rgb < 0.97, 0.97, 0.97 > }
    finish{ diffuse 0.9 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }
  
#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.80 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:
  
#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }
  
#declare corpo = 
  cylinder{
    < 0.00, 0.00, 0.00 >,
    < 0.00, 0.00, +2.00 >,
    1
    texture{ tx_fosca }
  }
  
#declare braco_dir = 
  cone{
    < +0.70, +0.70, +1.00 >, 0.3, 
    < +1.40, +1.40, +1.00 >, 0
    texture{ tx_fosca }
  }
  
#declare braco_esq = 
  cone{
    < +0.70, -0.70, +1.00 >, 0.3, 
    < +1.40, -1.40, +1.00 >, 0
    texture{ tx_fosca }
  }
  
#declare pesc_esq = 
  cone{
    < 0.00, -0.30, +1.70 >, 0.1, 
    < 0.00, -1.00, +2.50 >, 0.3
    texture{ tx_fosca }
  }
  
#declare pesc_dir = 
  cone{
    < 0.00, +0.30, +1.70 >, 0.1, 
    < 0.00, +1.00, +2.50 >, 0.3
    texture{ tx_fosca }
  }
   
#declare cab_esq =
  sphere{
    < 0.00, -1.25, +2.75 >, 0.60
    texture{ tx_fosca }
  }
    
#declare cab_dir =
  sphere{
    < 0.00, +1.25, +2.75 >, 0.60
    texture{ tx_fosca }
  }
  
#declare chif_esq = 
  cone{
    < 0.00, -1.60, +3.20 >, 0.15, 
    < 0.00, -2.00, +3.60 >, 0.0
    texture{ tx_chif }
  }
  
#declare chif_dir = 
  cone{
    < 0.00, +1.60, +3.20 >, 0.15, 
    < 0.00, +2.00, +3.60 >, 0.0
    texture{ tx_chif }
  }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{

  object{ eixos(3.00) }

  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }

  union {
     object{ corpo }
     object{ braco_dir }
     object{ braco_esq }
     object{ pesc_esq }
     object{ pesc_dir }
     object{ cab_esq }
     object{ cab_dir }
     object{ chif_esq }
     object{ chif_dir }
  }

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 2.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 3.00, 7.00 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)