// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_blue = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_green = 
  texture{
    pigment{ color rgb < 0.10, 1.00, 0.20 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 0.22
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:
  
#include "eixos.inc"

// Aqui está a cena, finalmente:

#local square_l = 2.5;
#local structure_h = 2.4;
#local big_sphere_r = 0.7;
#local small_sphere_r = 0.6;
#local small_box_l = 0.6;

union{
  object{ eixos(3.00) }

  box { <0,0,0>, <square_l,square_l,0.1> texture{ tx_fosca } }

  cylinder { <0.5,0.5,0>, <0.5,0.5,structure_h+0.6>, 0.12 texture{ tx_green } }
  torus { 0.22 0.1
          rotate <90,0,0>
          translate <0.5,0.5,structure_h>
          texture{ tx_blue } }
  cylinder { <0.5+0.12,0.5+0.12,structure_h>,
             <square_l/2-big_sphere_r/sqrt(2)+0.05,square_l/2-big_sphere_r/sqrt(2)+0.05,structure_h>,
             0.1
             texture{ tx_blue } }

  difference {
    sphere { <square_l/2, square_l/2, structure_h-0.1>, big_sphere_r }

    box { <0,0,structure_h-big_sphere_r-0.1>,
          <square_l,square_l,structure_h-0.1> }
    sphere { <square_l/2, square_l/2, structure_h-0.1>, small_sphere_r }

    texture{ tx_green }
  }

  difference {
    box { <-small_box_l/2,-small_box_l/2,-small_box_l/2>,
          <small_box_l/2,small_box_l/2,small_box_l/2>
          rotate <45,45,45>
          translate <square_l/2, square_l/2, -0.1>
          texture{ tx_xadrez } }

    box { <0,0,-1>, <square_l,square_l,0.1> }
  }

//  rotate <180,0,0>
}

#include "camlight.inc"
#declare centro_cena = < square_l/2, square_l/2, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 5.00, -3.00, 3.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)