// Last edited on 2013-11-04 00:41:35 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 2.000;

#declare cubo =
  box {
    < 0, 0, 0 >, < 4, 4, 4>
    texture {tx_vidro}
  }

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }

#declare cabeca =
  sphere{
    < 0.00, 0.00, 0.00 >, 1.5
  }

#declare buraco_cone =
  sphere{
    < 0.00, 0.00, 0.00 >, 1.8
  }

#declare cilindro =
  cylinder{
    <0.0, 0.0, 0.0>,
    <0.0, 5.0, 0.0>,
    1.0
  }

#declare cilindro_cone =
  cylinder{
    <0.0, -0.1, 0.0>,
    <0.0, 5.1, 0.0>,
    0.25
  }

#declare pernas =
  cylinder{
    <0.0, 0.0, 0.0>,
    <0.0, 0.0, 5.5>,
    0.25
  }

#declare buraco_cubo =
  cylinder{
    <0.0, 0.0, -0.01>,
    <0.0, 0.0, 4.01>,
    0.5
  }

#declare cone_estranho =
  cone {
    <0.0, 0.0, 0.0>, 2.0
    <0.0, 5.0, 0.0>, 1.0
  }

#declare rosquinha =
  torus {
    1.25
    0.5
  }

#declare esfera_rosca =
  sphere{
    < 0.00, 0.00, 0.00 >, 1.5
  }

#declare cilindro_rosca =
  cylinder{
    <0.0, 0.0, 0.0>,
    <0.0, 2.0, 0.0>,
    0.25
  }

#include "eixos.inc"

union{

  difference {
    difference {
      object{cone_estranho translate <2,-5,2> texture {tx_fosca}}
      object{buraco_cone translate <2, -2.5, 2> texture{tx_fosca}}
    }
    object{cilindro_cone translate <2, -5, 2> texture{tx_plastico}}
  }
  difference {
    object{cubo translate <0,0,0> texture{tx_plastico}}
    object{buraco_cubo translate <2, 2, 0> texture{tx_espelho}}
  }
  object{pernas translate <2, 1, -4.5> texture{tx_espelho}}
  object{pernas translate <2, 3, -4.5> texture{tx_espelho}}
  object{rosquinha rotate <90, -30, 0> translate <2, 2, -4.5> texture{tx_fosca}}
  object{cilindro_rosca translate <2, -1.5, -4.5> texture{tx_plastico}}
  intersection {
    object {rosquinha rotate <90, 0, 0> translate <2, -2.5, -4.5> texture{tx_plastico}}
    object {esfera_rosca translate <2, -2.5, -4.5>  texture{tx_fosca}}
  }
  union {
    object{cilindro translate <2, 4, 2> texture{tx_vidro}}
    object{cabeca translate<2, 9.5, 2> texture{tx_vidro}}
  }

  object{chao translate <1.5,1.5,-15> texture{tx_xadrez}}

}

#include "camlight.inc"
#declare centro_cena = < 2.00, 2.00, 0.00 >;
#declare raio_cena = 12.0;
#declare dir_camera = < -4.00, -2.00, 2.00 >;
#declare dist_camera = 25.0;
#declare intens_luz = 0.60;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)