// Last edited on 2013-11-04 01:15:57 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_ferro =
  texture{
    pigment{ color rgb < 1.00, 0.50, 0.10 > }
    finish{ diffuse 0.8 ambient 0.2 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.7 ambient 0.1 reflection 0.2*< 0.90, 0.92, 1.00 > }
    scale 4.0
  }

#declare raio = 2.000;

#declare rosca_main =
  cylinder{ < 0,0,0 >, < 0,0,10 >, 3 }

#declare rosca_volta =
  torus{ 3, 0.5 rotate < 90,0,0 > }

#declare rosca =
  difference{
    object{ rosca_main translate < 0,0,0 > }
    union{
      object{ rosca_volta translate < 0,0,0 >  }
      object{ rosca_volta translate < 0,0,2 >  }
      object{ rosca_volta translate < 0,0,4 >  }
      object{ rosca_volta translate < 0,0,6 >  }
      object{ rosca_volta translate < 0,0,8 >  }
      object{ rosca_volta translate < 0,0,10 > }
    }
  }

#declare main_base =
  cylinder{
    < 0,0,0 >,
    < 0,0,1.5 >,
    10
  }

#declare arm_support =
  box{
    < -1,-1,0 >,
    < +1,+1,15 >
  }

#declare arm_main =
  box{
    < -1,-1,0 >,
    < +1,+1,8 >
  }

#declare arm_ponta =
  sphere{
    < 0,0,0 >,
    1.7
  }

#declare arm_round =
  difference{
    object{ arm_main }
    object{ arm_ponta translate < 0,0,8.2 > }
  }

#declare arm =
  union{
    object{ arm_support }
    object{ arm_round rotate < 0,-130,0 > translate < 0,0,15 > }
  }

#declare lever_part1 =
  cylinder{
    < 0,0,0 >,
    < 0,0,6 >,
    0.8
  }

#declare lever_part2 =
  cylinder{
    < 0,0,0 >,
    < 0,0,5 >,
    0.6
    rotate < 0,-90,0 >
  }

#declare lever =
  union{
    object{ lever_part1 }
    object{ lever_part2 translate < 0,0,6 > }
  }

#declare foot =
  box{
    < -1,-1,0 >,
    < 1,1,8 >
  }

#declare chao =
  box{ <-20,-20,-1>, <+33,+33,0> }

#include "eixos.inc"

union{
  object{ chao texture{ tx_xadrez } }
  
  object{ rosca translate < 0,0,3 > texture{ tx_ferro } }
    
  union{
    object{ main_base translate < 0,0,8 > }
    object{ arm translate < 8.5,0,8 > rotate < 0,0,0 > }
    object{ arm translate < 8.5,0,8 > rotate < 0,0,120 > }
    object{ arm translate < 8.5,0,8 > rotate < 0,0,240 > }
    object{ foot translate < 8.5,0,0 > rotate < 0,0,60 > }
    object{ foot translate < 8.5,0,0 > rotate < 0,0,180 > }
    object{ foot translate < 8.5,0,0 > rotate < 0,0,300 > }
    object{ lever rotate < 0,90,0 > translate < 8.5,0,8 >
            rotate < 0,0,-30 > }
    object{ rosca_volta translate < 0,0,13.5 > }
    texture{ tx_fosca }
  }

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 11.00 >;
#declare raio_cena = 30.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 160.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)