// Last edited on 2013-11-04 18:53:09 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 1.0, 1.0, 1.0 > }

#declare tx_red =
texture{
        pigment{ color rgb < 0.90, 0.20, 0.20 > }
        finish{ diffuse 0.8 ambient 0.4 specular 0.5 roughness 0.005 }
}

#declare tx_blue =
texture{
        pigment{ color rgb < 0.30, 0.30, 1.0 > }
        finish{ diffuse 0.8 ambient 0.5 specular 0.7777777 roughness 0.005 }
}

#declare tx_green =
texture{
        pigment{ color rgb < 0.20, 0.90, 0.20 > }
        finish{ diffuse 0.8 ambient 0.4 specular 0.5 roughness 0.005 }
}

#declare tx_steel =
texture{
        pigment { rgb <0.55, 0.5, 0.45> }
        finish { metallic ambient 0.1 diffuse 0.65 specular 0.85 roughness 0.01 reflection 0.45 brilliance 1.5}
}

#declare tx_black =
texture{
        pigment{ color rgb < 0.60, 0.30, 0.60 > }
        finish{ diffuse 0.5 ambient 0.2 }
}

#declare zero = 0.0000001;
#declare buttonH = 1;
#declare buttonR = 1;
#declare leverH = 5;
#declare leverR = 1;
#declare leverS = 1.5;
#declare switS = 1.5;
#declare panelH = 50;
#declare panelW = 10;
#declare panelL = 90;
#declare screenH = 15;
#declare screenW = 1;
#declare screenL = 25;
#declare surface = panelW/2+zero;
#declare left = -9*panelL/20;
#declare top = 9*panelH/20;
#declare slotsB = 14;
#declare linesB = 11;
#declare slotsA = 11;
#declare linesA = 8;

#declare panelBack =
difference {
        box {<0,0,0>, <panelL,panelW,panelH> translate<-panelL/2,-panelW/2,-panelH/2> texture {tx_red}}
        box {<0,0,0>, <screenL,screenW,screenH> translate<panelL/6, surface-screenW, panelH/6> texture {tx_blue} }
}

#declare button =
cylinder{ < 0,0,0 >, <0,buttonH,0>, buttonR }

#declare lever =
union {
        cylinder{ < 0,0,0 >, <0,leverH,0>, leverR }
        sphere {<0,leverH,0>, leverS}

        rotate <45,0,0>
}

#declare swit =
        box {<0,0,0>, <switS,switS,switS> rotate <45,0,0> texture {tx_steel}}

#macro panel (K,D)

union{
        object{ panelBack translate<0,0,0> }

#declare h=0;

#declare i=0;
#while (i<linesB)
#if ((i+D)=linesB/2)
#else
        #declare j=0;
        #while (j<slotsB)
                #if (mod(i+D+j+(j*i)/2,K+(i/3))=0)
                        object { lever rotate<0,180*mod(h,2),0> translate <j*4+left,surface,top-i*4> texture {tx_steel}}
                        #declare h=h+1;
                #else
                        object { button translate <j*4+left,surface,top-i*4> texture {tx_steel}}
                #end
                #declare j=j+1;
        #end
#end
#declare i=i+1;
#end

#declare i=0;
#while (i<linesA)
#if ((i+D)=linesA/2)
#else
        #declare j=0;
        #while (j<slotsA)
                #if (mod(i+D+j+(j*i)/2,K+(i/3))=0)
                        object { lever rotate<0,180*mod(h,2),0> translate <-j*4-left,surface,-top+i*4> texture {tx_steel}}
                        #declare h=h+1;
                #else
                        object { swit translate <-j*4-left,surface,-top+i*4> texture {tx_steel}}
                #end
                #declare j=j+1;
        #end
#end
#declare i=i+1;
#end

}
#end

#include "eixos.inc"
union {
        object{ eixos(5.00) }
        object{ panel(5,1) }

        scale <0.1,0.1,0.1>
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 2, 10, 6 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)