// Last edited on 2013-11-04 19:08:02 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.60, 0.05 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 3.00, 3.00, 3.00 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 2.000;

#declare botao =
  cylinder {
    <0,0,0>,
    <0,0.5,0>,
    0.25
  }

#declare chave =
  union {
    cylinder {
      <0,0,0>,
      <0,0.25,-0.25>,
      0.1
    }
    box {
      <-0.25, 0, 0.25>,
      <0.25, -0.2, -0.25>
    }
  }

#include "eixos.inc"

#macro painel (largura)

union{
  
  #declare quadro =
  box{ <0, 0, 10>, <3*largura + 5, -1, 0> texture{tx_fosca}}

  object{quadro translate <-10, -0.2, -5>}

  #declare i = 0;
  #while ( i < largura )
    #if (mod(i,2) = 0)
      object{botao translate <2*i, 0, 1.0> texture{tx_plastico}}
    #else
      object{botao translate <2*i, 0, 1.0> texture{tx_vidro}}
    #end
    #declare i = i + 1;
  #end

  #declare i = 0;
  #while ( i < largura )
    object{chave translate <2*i, 0, 0> texture{tx_plastico}}
    #declare i = i + 1;
  #end

  #declare i = 0;
  #while ( i < largura )
    #if (mod(i,2) = 0)
      object{botao translate <2*i, 0, -1.0> texture{tx_vidro}}
    #else
      object{chave translate <2*i, 0, -1.0> texture{tx_plastico}}
    #end
    #declare i = i + 1;
  #end

  #declare i = 0;
  #while ( i < largura )
    #if (mod(i,2) = 0)
      object{botao translate <2*i, 0, -2.0> texture{tx_vidro}}
    #else
      #if (mod(i,3) = 0)
        object{chave translate <2*i, 0, -2.0> texture{tx_plastico}}
      #else
        object{chave rotate <0, 180, 0> translate <2*i, 0, -2.0> texture{tx_plastico}}
      #end
    #end
    #declare i = i + 1;
  #end

  #declare i = 0;
  #while ( i < 2 )
    object{botao scale<2,2,2> translate <-2*i -2, 0, 0.5> texture{tx_plastico}}
    #declare i = i + 1;
  #end
  #declare i = 0;
  #while ( i < 2 )
    object{botao scale<0.5,0.5,0.5> translate <-0.5*i -1.5, 0, -1.0> texture{tx_plastico}}
    object{botao scale<0.5,0.5,0.5> translate <-0.5*i -1.5, 0, -1.5> texture{tx_plastico}}
    #declare i = i + 1;
  #end
  object{chave scale<1.5,1.5,1.5> translate <-3.5, 0, -1.0> texture{tx_vidro}}
  box { <0,0,0> <4,-0.3, -0.5> translate <-4.5, 0, -2.5> texture{tx_espelho}}
  
  //object{ eixos(10) }

}
#end

painel(8)

#include "camlight.inc"
#declare centro_cena = < 2.5, 0.50, 0.50 >;
#declare raio_cena = 17.0;
#declare dir_camera = < -4.00, 8.00, 3.00 >;
#declare dist_camera = 50.0;
#declare intens_luz = 0.60;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)