// Last edited on 2013-11-04 19:19:35 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.90, 0.90, 0.90 > }
    finish{ diffuse 0.8 ambient 0.4 specular 0.5 roughness 0.005 }
  }

#declare tx_casca =
  texture{
    pigment{ color rgb < 0, 0.7, 0.00 > }
    finish{ diffuse 0.5 ambient 0.3 specular 0.1 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca_prata =
  texture{
    pigment{ color rgb < 0.80, 0.80, 0.80 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 1.0, 1.0 > }
    finish{ diffuse 0.5 reflection 0.7*< 1.0, 1.0, 1.0 > ambient 0.7 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

#declare relogio =
  union{
    difference {
      cylinder { <0, 0, 0>, <0, 0, 0.1>, 1.0 }
      cylinder { <0, 0, 0.06>, <0, 0, 0.2>, 0.8 texture { tx_plastico } }
    }
    union {
      box { <-0.1, -0.1, 0.06>, <0.6, 0.1, 0.12> }
      difference {
        box { <-0.15, -0.15, 0.06>, <0.15, 0.15, 0.12> rotate <0, 0, 45> }
        box { <0, -1, 0>, <-1, 1, 1> }
        translate <0.6, 0, 0>
      }
    }
    cylinder { <0, 0, 0>, <0, 0, 0.2>, 0.03 texture { tx_vidro } }
    scale <0.8, 0.8, 0.8>
  }

#declare botao =
  union {
    cylinder { <0, 0, 0>, <0, 0, 0.3>, 0.6 texture {tx_vidro} }
    cylinder { <0, 0, 0>, <0, 0, 0.4>, 0.5 }
  }

#declare interruptor =
  union {
    box { <-0.6, -0.3, 0>, <0.6, 0.3, 0.3> texture {tx_vidro} }
    difference {
      cylinder { <0, -0.25, 0.35>, <0, 0.25, 0.35>, 0.55 }
      union {
        box { <-1, -1, -1>, <1, 1, 0> }
        box { <-1, -1, 0.35>, <0, 1, 1> }
        box { <0, -1, 0.0>, <1, 1, 1> rotate <0, -20, 0> translate <0, 0, 0.35> }
      }
    }
  }

#declare alavanca =
  difference {
    union {
      difference {
        box { <-1, -0.5, 0>, <1, 0.5, 0.3> texture {tx_vidro} }
        box { <-0.75, -0.25, 0>, <0.75, 0.25, 0.4> texture {tx_vidro} }
      }
      union {
        cylinder { <0, 0, 0>, <0, 0, 2>, 0.2 }
        sphere { <0, 0, 2>, 0.3 }
        rotate <0, 30, 0>
        translate <0, 0, -0.5>
      }
    }
    box { <-10, -10, -10>, <10, 10, 0> }
  }

#declare RANDGEN = seed(11530);

#macro control(I)
  #if (I = 0)
    object{relogio texture{ tx_fosca } rotate <0, 0, int(360*rand(RANDGEN))>}
  #end
  #if (I = 1)
    object{botao texture{ tx_fosca_prata }}
  #end
  #if (I = 2)
    object{interruptor texture{ tx_fosca_prata }}
  #end
  #if (I = 3)
    object{alavanca texture{ tx_fosca_prata }}
  #end
#end

#macro subpainel()
  union {
    box { <-2, -2, 0>, <2, 2, 0.5> texture {tx_plastico} }
    union { control(int(4*rand(RANDGEN))) translate <-1, -1, 0.5> }
    union { control(int(4*rand(RANDGEN))) translate <-1, 1, 0.5> }
    union { control(int(4*rand(RANDGEN))) translate <1, -1, 0.5> }
    union { control(int(4*rand(RANDGEN))) translate <1, 1, 0.5> }
    rotate <0, 90, 0>
    translate <0, 0, 2>
  }
#end

#macro painel(M, N)
  union {
    box { <-1, 0, 0>, <0, M*5, N*5> texture { tx_fosca_prata } }
    #declare i = 0;
    #while (i < M)

      #declare j = 0;
      #while (j < N)

        union {
          subpainel()
          translate <0, 2.5+5*i, 5*j>
        }

      #declare j = j+1;
      #end

    #declare i = i+1;
    #end
    translate <0, -2.5*M, 0>
  }
#end

union{

  object{ chao  translate < 0,0,0 > texture{ tx_xadrez } }
  eixos(10)
  painel(5, 3)
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 7.00 >;
#declare raio_cena = 19.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 60.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)