// Last edited on 2013-11-04 20:27:47 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.10, 0.30, 0.10 > }

#declare tx_painel = texture {
  pigment {
    color rgb < 0.66, 0.66, 0.66 >
  }
  finish {
    diffuse 0.8 ambient 0.1 specular 0.1 roughness 0.005
  }
}
#declare tx_botao = texture {
  pigment {
    color rgb < 0.88, 0.88, 0.88 >
  }
  finish {
    diffuse 0.8 ambient 0.1 specular 0.1 roughness 0.005
  }
}
#declare tx_visor = texture {
  pigment {
    color rgb < 0.00, 0.00, 0.00 >
  }
  finish {
    diffuse 0.8 ambient 0.1 specular 0.2 roughness 0.05 reflection 0.2
  }
}

#declare largura_painel = 7;
#declare altura_painel = 4;
#declare espessura_painel = 1;
#declare tam_deslizante = 1;
#declare tam_deslizante_marcador = 0.18;
#declare largura_visor = 3;
#declare altura_visor = 1.2;

#declare painel = box {
  < -largura_painel / 2, -espessura_painel, -altura_painel / 2 >
  < largura_painel / 2, 0, altura_painel / 2 >
  texture { tx_painel }
}
#declare botao = prism {
  conic_sweep
  0.7,
  1,
  5,
  <0.1,0.1>,<-0.1,0.1>,<-0.1,-0.1>,<0.1,-0.1>,<0.1,0.1>
  scale < 1, 0.4, 1>
  rotate < 0, 0, 180 >
  translate < 0, 0.41, 0 >
  texture { tx_botao }
}
#declare deslizante = box {
  < -0.02, -0.02, tam_deslizante / 2 >
  < 0.02, 0.02, - tam_deslizante / 2 >
  pigment { color rgb < 0, 0, 0 > }
}
#declare deslizante_marcador = box {
  < -tam_deslizante_marcador / 2, tam_deslizante / 4, -0.05 >
  < tam_deslizante_marcador / 2, - tam_deslizante / 4, 0.05 >
  pigment { color rgb < 0.33, 0.33, 0.33 > }
}
#declare alavanca = box {
  < -0.1, -0.1, tam_deslizante / 2 >
  < 0.1, 0.1, - tam_deslizante / 2 >
  pigment { color rgb < 0, 0, 0 > }
}
#declare visor = box {
  < -largura_visor / 2, -0.1, altura_visor/ 2 >
  < largura_visor / 2, 0.1, - altura_visor / 2 >
  pigment { color rgb < 0, 0, 0 > }
}

#macro escrever(pos_painel,texto)
#declare letras = array[30] {"A","B","C","D","E","F","G","H","I","J","K","L","M","N","O","P","Q","R","S","T","U","V","W","X","Y","Z","_","!",":",")"};
#declare pos_botoes = pos_painel + < -3, 0, 1.5 >;
#declare pos_deslizantes = pos_painel + < -3, 0, 0.7 >;
#declare pos_visor = pos_painel + < -1.5, -0.07, -1 >;
  object {
    painel
  }
#declare i=0;
#while (i < 30)
  object {
    botao translate pos_botoes + < 0.2 * i, 0, 0 >
    #if (texto[29-i] > 0)
      scale < 1, 0.5, 1 >
    #end
  }
  object {
    text {
      ttf "cyrvetic.ttf" letras[29-i] 0.1, 0
      pigment { color rgb < 0, 0, 0 > }
    }
    scale < 0.1, 0.1, 0.1 >
    rotate < 90, 0, 180 >
    translate pos_botoes + < 0.04 + 0.2 * i, 0.14, -0.03 >
    #if (texto[29-i] > 0)
      scale < 1, 0.5, 1 >
    #end
  }
  object {
    deslizante translate pos_deslizantes + < 0.2 * i, 0, 0 >
  }
  object {
    deslizante_marcador translate pos_deslizantes + < 0.2 * i, 0, -0.4 + texto[29-i] * 0.1 >
  }
  #declare i=i+1;
#end
  object {
    visor translate pos_visor
  }
#declare i = 0;
#while (i < 30)
  #if (texto[i] > 0)
  object {
    text {
      ttf "cyrvetic.ttf" letras[i] 0.1, 0
      pigment { color rgb < 1, 1, 0 > }
    }
    scale < 0.5, 1, 1 >
    rotate < 90, 0, 180 >
    translate pos_visor + < 1.8 - 0.4 * texto[i], 0.01, -0.3 >
  }
  #end
  #declare i=i+1;
#end
#end

#declare pos_painel = < 0, 0, 0 >;

union{
  escrever(pos_painel,array[30] {7,1,0,5,0,0,0,0,6,0,0,0,3,0,2,0,0,0,0,0,0,0,0,0,0,0,4,0,0,0})
}

#include "camlight.inc"
#declare centro_cena = pos_painel;
#declare raio_cena = 5.5;
#declare dir_camera = < 0.5, 1, 0.05 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)