// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_cristal =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_wall =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.80 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 2.000;
#declare roleta = seed(1000);

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }

#macro castelo(p, pmin, xx, yy, zz, tam)
   #if (p > pmin)
      #local pnovo = p-1;
      #local tamnovo = tam/3;
      #local znovo = zz+tam/2;
      #local x1 = xx;
      #local y1 = yy;
      #local x2 = xx+ 2*tam/3;
      #local y2 = yy;
      #local x3 = xx;
      #local y3 = yy+ 2*tam/3;
      #local x4 = xx+ 2*tam/3;
      #local y4 = yy+ 2*tam/3;
      #local p1 = rand(roleta);
      #if (p1 < 0.5)
         #local p1 = p1+0.5;
      #end

      #local p2 = rand(roleta);
      #if (p2 < 0.5)
         #local p2 = p2+0.5;
      #end

      #local p3 = rand(roleta);
      #if (p3 < 0.5)
         #local p3 = p3+0.5;
      #end

      #local p4 = rand(roleta);
      #if (p4 < 0.5)
         #local p4 = p4+0.5;
      #end
      union {
         box{
            < xx, yy, zz >, <xx + tam, yy + tam, zz + tam/2>
            texture { tx_wall }
         }
         cone{
            < xx+tam/2, yy+tam/2, zz+tam/2 >, tam/6,
            < xx+tam/2, yy+tam/2, zz+tam   >, 0.0
            texture{ tx_cristal }
         }
         object{castelo(pnovo, pmin, x1, y1, znovo, tamnovo*p1)}
         object{castelo(pnovo, pmin, x2, y2, znovo, tamnovo*p2)}
         object{castelo(pnovo, pmin, x3, y3, znovo, tamnovo*p3)}
         object{castelo(pnovo, pmin, x4, y4, znovo, tamnovo*p4)}
      }
   #else
      union {
         box{
            < xx, yy, zz >, <xx + tam, yy + tam, zz + tam/2>
            texture { tx_wall }
            }
         cone{
            < xx+tam/2, yy+tam/2, zz+tam/2 >, tam/6,
            < xx+tam/2, yy+tam/2, zz+tam   >, 0.0
            texture{ tx_cristal }
         }
      }
   #end
#end

#include "eixos.inc"

union{

  object{ eixos(3.00) }

  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }

   object{castelo(5, 1, 0.0, 0.0, 0.0, 5.0)}
}
#include "camlight.inc"
#declare centro_cena = < +5.50, +5.50, -2.00 >;
#declare raio_cena = 9.0;
#declare dir_camera = < -1.00, -2.00, 2.00 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)