// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_blue =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_black =
  texture{
    pigment{ color rgb < 0.20, 0.20, 0.20 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 0.22
  }

#include "glass.inc"
#include "eixos.inc"
#include "retalho.inc"

#declare Ar = array[4][4] {
  {<-0.5,0,4>, <0,1,4>, <-0.2,2,4>, <-0.3,3,4>},
  {<-0.1,0,2>, <-0.1,1,2>, <-0.1,2,2>, <-0.1,3,2>},
  {<-1.5,0,-1.5>, <-1.5,1,-1.5>, <-1.5,2,-1.5>, <-1.5,3,-1.5>},
  {<3.3,0,0.2>, <3.6,1,0.2>, <3.4,2,0.2>, <3.3,3,0.2>}
};
#declare Al = array[4][4] {
  {<-0.5,6,4>, <0,5,4>, <-0.2,4,4>, Ar[0][3]},
  {<-0.1,6,2>, <-0.1,5,2>, <-0.1,4,2>, Ar[1][3]},
  {<-1.5,6,-1.5>, <-1.5,5,-1.5>, <-1.5,4,-1.5>, Ar[2][3]},
  {<3.3,6,0.2>, <3.6,5,0.2>, <3.4,4,0.2>, Ar[3][3]}
};

#declare Br = array[4][4] {
  {Ar[3][0], Ar[3][1], Ar[3][2], Ar[3][3]},
  {<3.6,0,-0.5>, <3.6,1,-0.5>, <3.6,2,-0.5>, <3.6,3,-0.5>},
  {<1,0,-1>, <1,1,-1>, <1,2,-1>, <1,3,-1>},
  {<-1.3,0,-1>, <-1.3,1,-1>, <-1.3,2,-1>, <-1.3,3,-1>}
};
#declare Bl = array[4][4] {
  {Al[3][0], Al[3][1], Al[3][2], Al[3][3]},
  {<3.6,6,-0.5>, <3.6,5,-0.5>, <3.6,4,-0.5>, Br[1][3]},
  {<1,6,-1>, <1,5,-1>, <1,4,-1>, Br[2][3]},
  {<-1.3,6,-1>, <-1.3,5,-1>, <-1.3,4,-1>, Br[3][3]}
};

#declare Cr = array[4][4] {
  {Ar[0][0], Ar[0][1], Ar[0][2], Ar[0][3]},
  {<-1,0,4.5>, <-1,1,4.5>, <-1,2,4.5>, <-1,3,4.5>},
  {<-2,0,2>, <-2,1,2>, <-2,2,2>, <-2,3,2>},
  {Br[3][0], Br[3][1], Br[3][2], Br[3][3]}
};
#declare Cl = array[4][4] {
  {Al[0][0], Al[0][1], Al[0][2], Al[0][3]},
  {<-1,6,4.5>, <-1,5,4.5>, <-1,4,4.5>, Cr[1][3]},
  {<-2,6,2>, <-2,5,2>, <-2,4,2>, Cr[2][3]},
  {Bl[3][0], Bl[3][1], Bl[3][2], Bl[3][3]}
};

#macro desenha_retalho(M)
  retalho(M[0][0], M[0][1], M[0][2], M[0][3],
          M[1][0], M[1][1], M[1][2], M[1][3],
          M[2][0], M[2][1], M[2][2], M[2][3],
          M[3][0], M[3][1], M[3][2], M[3][3],
          0.01, tx_fosca, tx_blue)

#end

union{
  object{ eixos(3.00) }

  object{ desenha_retalho(Ar) }
  object{ desenha_retalho(Al) }
  object{ desenha_retalho(Br) }
  object{ desenha_retalho(Bl) }
  object{ desenha_retalho(Cr) }
  object{ desenha_retalho(Cl) }

  torus{ 1 0.5
         translate <-0.2,-0.5,-0.4>
         texture{ tx_black } }

  torus{ 1 0.5
         translate <-0.2,6.5,-0.4>
         texture{ tx_black } }
}

#include "camlight.inc"
#declare centro_cena = < 0, 3, 1.2 >;
#declare raio_cena = 7;
#declare dir_camera = < 4.00, -3.00, 2.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)