// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.90, 0.90, 0.90 > }
    finish{ diffuse 0.8 ambient 0.4 specular 0.5 roughness 0.005 }
  }

#declare tx_casca =
  texture{
    pigment{ color rgb < 0, 0.7, 0.00 > }
    finish{ diffuse 0.5 ambient 0.3 specular 0.1 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca_prata =
  texture{
    pigment{ color rgb < 0.80, 0.80, 0.80 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 1.0, 1.0 > }
    finish{ diffuse 0.5 reflection 0.7*< 1.0, 1.0, 1.0 > ambient 0.7 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

#macro interpola2(p, tt)
  ((1-tt)*p[0]+tt*p[1])
#end

#macro interpola4(p, tt)
  #local p01 = interpola2(array[2]{p[0], p[1]}, tt);
  #local p12 = interpola2(array[2]{p[1], p[2]}, tt);
  #local p23 = interpola2(array[2]{p[2], p[3]}, tt);
  #local p012 = interpola2(array[2]{p01, p12}, tt);
  #local p123 = interpola2(array[2]{p12, p23}, tt);
  #local p0123 = interpola2(array[2]{p012, p123}, tt);
  p0123
#end

#macro bezier(P, R, N)
  union {
    #local T = 0.0;
    #while (T <= 1.0)
      sphere { interpola4(P, T),
               interpola2(R, T)}
    #local T = T + 1.0/N;
    #end
  }
#end

#macro tentaculo(P)
  union {
    #local P1 = array[4]
      { P[0], P[1], P[2], (P[2]+P[3])/2 }
    #local P2 = array[4]
      { (P[2]+P[3])/2, P[3], P[4], P[5] }

    bezier(P1, array[2]{ 0.16, 0.13 }, 1000)
    bezier(P2, array[2]{ 0.13, 0.0 }, 1000)
  }
#end

#macro tentaculo_animado(PP, tt)
  #local p0 = interpola4(array[4]{ PP[0][0], PP[1][0], PP[2][0], PP[3][0] }, tt);
  #local p1 = interpola4(array[4]{ PP[0][1], PP[1][1], PP[2][1], PP[3][1] }, tt);
  #local p2 = interpola4(array[4]{ PP[0][2], PP[1][2], PP[2][2], PP[3][2] }, tt);
  #local p3 = interpola4(array[4]{ PP[0][3], PP[1][3], PP[2][3], PP[3][3] }, tt);
  #local p4 = interpola4(array[4]{ PP[0][4], PP[1][4], PP[2][4], PP[3][4] }, tt);
  #local p5 = interpola4(array[4]{ PP[0][5], PP[1][5], PP[2][5], PP[3][5] }, tt);
  #local P = array[6] {p0, p1, p2, p3, p4, p5}
  tentaculo(P)
#end

union{

  object{ chao  translate < 0,0,0 > texture{ tx_xadrez } }

  #local PP = array[4][6]
  { {<+0.0, +0.0, +0.5>,
     <+0.0, +1.0, +0.0>,
     <+0.0, +1.0, +1.5>,
     <+0.0, +2.5, +1.5>,
     <+0.0, +2.5, +0.0>,
     <+0.0, +3.5, +1.0>},
    {<+0.0, +0.0, +0.5>,
     <+0.0, +1.0, -0.5>,
     <+0.0, +1.0, +2.0>,
     <+0.0, +2.5, +2.0>,
     <+0.0, +2.5, +0.0>,
     <+0.0, +4.0, +1.0>},
    {<+0.0, +0.0, +0.5>,
     <+0.0, +1.0, +0.5>,
     <+0.0, +1.0, +1.0>,
     <+0.0, +2.5, +1.0>,
     <+0.0, +2.5, +0.0>,
     <+0.0, +3.0, +1.0>},
    {<+0.0, +0.0, +0.5>,
     <+0.0, +1.0, +0.0>,
     <+0.0, +1.0, +1.5>,
     <+0.0, +2.5, +1.5>,
     <+0.0, +2.5, +0.0>,
     <+0.0, +3.5, +1.0>} }

  #declare RANDGEN = seed(1134);

  union {
    sphere { <0, 0, 0.75>, 0.5 scale <1.0, 1.0, 1.5> }

    #local i = 0;
    #while (i<360)
      object { tentaculo_animado(PP, mod(clock+rand(RANDGEN), 1.0)) rotate <0, 0, i> translate <0, 0, 0> }
    #local i = i+360/8;
    #end
    texture { tx_fosca }
  }

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 5.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 24.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)