// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 2.000;

#declare bolinha =
  sphere{ < 0,0,0 >, 0.60 }

#declare bolota =
  sphere{ < 0,0,0 >, 1.50 }

#declare bola =
  sphere{
    < 0.00, 0.00, 0.00 >, raio
    texture{ tx_plastico }
  }

#declare pino =
  cylinder{
    < -2.00, +2.00, -1.00 >,
    < +2.00, -2.00, +1.00 >,
    0.75
    texture{ tx_fosca }
  }

#declare furo =
  cylinder{
    < -1.00, -2.00, -2.00 >,
    < +1.00, +2.00, +2.00 >,
    0.75*raio
    texture{ tx_fosca }
  }

#include "eixos.inc"

#macro mina (m,n)
union{

  #declare camara_min_size = 1;
  #declare camara_max_size = 4;
  #declare camara_min_x = -100;
  #declare camara_max_x = 100;
  #declare camara_min_y = -100;
  #declare camara_max_y = 100;
  #declare camara_min_z = -100;
  #declare camara_max_z = 100;
  #declare tunel_min_size = 0.3;
  #declare tunel_max_size = 0.8;

  #declare camara_d = array[m]
  #declare camara_r = array[m]

  #declare roleta0 = seed(m*n);

  #declare i=0;
  #while (i<m)
    #declare camara_d[i] = <camara_min_x + 2*rand(roleta0) * camara_max_x,camara_min_y + 2*rand(roleta0) * camara_max_y,camara_min_z +  2*rand(roleta0) * camara_max_z>;
    #declare camara_r[i] = camara_min_size + rand(roleta0) * camara_max_size;

    #declare i = i+1;
  #end

  #declare i=0;
  #while (i<m)
    sphere {camara_d[i], camara_r[i] texture{tx_plastico}}
    #declare i = i+1;
  #end

  #declare i=0;
  #while(i<n)
    #declare t1=0;
    #declare t2=0;

    #while(t1=t2)
      #declare t1 = int(rand(roleta0)*m);
      #declare t2 = int(rand(roleta0)*m);
    #end

    cylinder{camara_d[t1],camara_d[t2],(tunel_min_size + rand(roleta0)*tunel_max_size) texture{tx_fosca}}
    #declare i=i+1;
  #end

  cylinder{camara_d[0],<camara_d[0].x,camara_d[0].y,160>,(tunel_min_size +   rand(roleta0)*tunel_max_size) texture{tx_fosca}}

}
#end

object{mina(50,40)}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 200;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 200*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)