// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2017-05-07 20:10:09 by stolfilocal

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.968, 0.784, 0.631> }

// cor construção
#declare cor_construcao = 
  texture{
    pigment{ color rgb < 0.639, 0.639, 0.639 > }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================

#macro mina(n,m)
		// DESCRIÇÃO DA CENA 

		#declare i = 0;
		#declare roleta1 = seed(n);
		#declare centro = array[n];

		//Criação do vetor das câmaras
		#while(i<n)
			#declare centro[i] = <100*rand(roleta1),100*rand(roleta1),100*rand(roleta1)>;
			#declare i = i+1;
		#end
		
		//Procurando a camara mais alta (de maior z)
		#declare ind_maior= centro[0];
		#declare i=1;
		#while(i<n)
			#if (centro[i].z > ind_maior.z)
				#declare ind_maior= centro[i];
			#end
			#declare i = i+1;
		#end
		
	union{
		//Geração das câmaras
		#declare i=0;
		#while(i<n)
			sphere{
					centro[i],
					2.0 
					texture{ cor_construcao }
					}
			#declare i = i+1;
		#end

		//Geração dos tuneis conectando as câmaras
		#declare i=0;
		#while(i<n)
			#declare p1 = int(n*rand(roleta1));
			#declare p2 = int(n*rand(roleta1));
			#if(p1 != p2)
				 cylinder{
					centro[p1],
					centro[p2],
					0.15
					texture{ cor_construcao }
					}
				 #declare i=i+1;
			#end
		#end
		
		//Geração do tunel de entrada
			 cylinder{
					ind_maior,
					<ind_maior.x,ind_maior.y,ind_maior.z+100>,
					0.15
					texture{ cor_construcao }
					}
	}
#end

object{mina(50,50)}
// ======================================================================


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 26.00 >;
#declare raio_cena = 100.0;
#declare dir_camera = < 7.00, 7.00, 4.00 >;
#declare dist_camera = 1000*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)