// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2017-05-07 20:10:09 by stolfilocal

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.8, 0.7, 0.5 > }
    

#declare tx_saida = 
    texture{
     pigment{ color rgb < 0.3, 0.1, 0.1 > }
     finish{ diffuse 0.9 ambient 0.1 }
}


#declare tx_mina =
	texture{
    pigment{ color rgb < 0.25, 0.25, 0.3 > }
    finish{ diffuse 1 reflection 0 ambient 0.2 }
    scale 2.0
  }


// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#macro mina(nCamaras, nTuneis)
	union{
		#declare SEED = seed(now * 100000);
		#declare posicoes = array[nCamaras];
		#declare tamanhos = array[nCamaras];

		//Criação das câmaras
		#declare i=0;
		#while ( i < nCamaras )
			#declare posicoes[i] = <50*rand(SEED), 50*rand(SEED), 40*rand(SEED)>;
			#declare tamanhos[i] = 2+2*rand(SEED);
			object{ box {posicoes[i], posicoes[i] + <tamanhos[i],tamanhos[i],tamanhos[i]> texture {tx_mina}}}
			#declare i = i + 1;
		#end
		
		//Criação dos túneis de conexão
		#declare i=0;
		#while (i < nTuneis)
			#declare origem = int(rand(SEED)*nCamaras);
			#declare alvo = int(rand(SEED)*nCamaras);
			
			#if (origem != alvo)
				object{ cylinder {posicoes[origem],posicoes[alvo],0.6 texture{tx_mina}}}
				#declare i = i + 1;
			#else
			#end
		#end
	
		//Criação da entrada da mina
		#declare posicaoSaida = posicoes[0] + tamanhos[0]/2;
		object{ cylinder {posicaoSaida, posicaoSaida + <0,0,100>, 0.6 texture {tx_saida}}}
	}
#end

#include "eixos.inc"

// CENA

union{
	//object{ eixos(3.00) }
	object{ mina(10, 21) }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 50.0;
#declare dir_camera = < 1.0, 1.0, 1.0 >;
#declare dist_camera = 10*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)