// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.5, 0.5, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0,0,0 >, color rgb < 1,1,1 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRICAO DA CENA 

#declare passos = 100;
#declare ints = 5;
#declare intf = ints;

#macro interpolin(t0, v0, t1, v1, tt)
	#local r = (tt-t0)/(t1-t0);
	#local s = 1-r;
	#local vv = s*v0 + r*v1;
	
	vv
#end

#macro arcobezier(t0, t1, A, B, C, D, tt)
	#local AB = interpolin(t0, A, t1, B, tt);
	#local BC = interpolin(t0, B, t1, C, tt);
	#local CD = interpolin(t0, C, t1, D, tt);
	
	#local ABC = interpolin(t0, AB, t1, BC, tt);
	#local BCD = interpolin(t0, BC, t1, CD, tt);
	
	#local ACBD = interpolin(t0, ABC, t1, BCD, tt);
	
	ACBD
#end

#macro curva(p0, p1, v0, v1)
	#local i = 0;
	#while(i <= passos)
		#local p = arcobezier(0, passos, p0, p0+v0, p1-v1, p1, i);
		
		sphere{ p, 0.5 texture{tx_fosca}}
		
		#declare i = i+1;
	#end
	//cylinder{ t0, t1, 0.5 texture{tx_fosca}}
#end




// Cena final

/*union{
	curva(<-10, 0, 0>, <-2.5, 10, 0>, <0, 0, 0>, <0, 0, 0>)
	curva(<-2.5, 10, 0>, <2.5, 2.5, 2.5>, <0, 0, 0>, <0, 0, 0>)
	curva(<2.5, 2.5, 2.5>, <0, -2.5, 0>, <0, 0, 0>, <0, 0, 0>)
	curva(<0, -2.5, 0>, <-2.5, 2.5, -2.5>, <0, 0, 0>, <0, 0, 0>)
	curva(<-2.5, 2.5, -2.5>, <2.5, 10, 0>, <0, 0, 0>, <0, 0, 0>)
	curva(<2.5, 10, 0>, <10, 0, 0>, <0, 0, 0>, <0, 0, 0>)
	curva(<10, 0, 0>, <2.5, -10, 0>, <0, 0, 0>, <0, 0, 0>)
	curva(<2.5, -10, 0>, <-2.5, -2.5, 2.5>, <0, 0, 0>, <0, 0, 0>)
	curva(<-2.5, -2.5, 2.5>, <0, 2.5, 0>, <0, 0, 0>, <0, 0, 0>)
	curva(<0, 2.5, 0>, <2.5, -2.5, -2.5>, <0, 0, 0>, <0, 0, 0>)
	curva(<2.5, -2.5, -2.5>, <-2.5, -10, 0>, <0, 0, 0>, <0, 0, 0>)
	curva(<-2.5, -10, 0>, <-10, 0, 0>, <0, 0, 0>, <0, 0, 0>)
}*/

union{
	curva(<-10, 0, 0>, <-2.5, 10, 1>, <0, intf, 0>, <intf, 0, 0>)
	curva(<-2.5, 10, 1>, <2.5, 2.5, 2.5>, <intf, 0, 0>, <0, -ints, 0>)
	curva(<2.5, 2.5, 2.5>, <0, -2.5, 0>, <0, -ints, 0>, <-ints, 0, 0>)
	curva(<0, -2.5, 0>, <-2.5, 2.5, -2.5>, <-ints, 0, 0>, <0, ints, 0>)
	curva(<-2.5, 2.5, -2.5>, <2.5, 10, -1>, <0, ints, 0>, <intf, 0, 0>)
	curva(<2.5, 10, -1>, <10, 0, 0>, <intf, 0, 0>, <0, -intf, 0>)
	curva(<10, 0, 0>, <2.5, -10, 1>, <0, -intf, 0>, <-intf, 0, 0>)
	curva(<2.5, -10, 1>, <-2.5, -2.5, 2.5>, <-intf, 0, 0>, <0, ints, 0>)
	curva(<-2.5, -2.5, 2.5>, <0, 2.5, 0>, <0, ints, 0>, <ints, 0, 0>)
	curva(<0, 2.5, 0>, <2.5, -2.5, -2.5>, <ints, 0, 0>, <0, -ints, 0>)
	curva(<2.5, -2.5, -2.5>, <-2.5, -10, -1>, <0, -ints, 0>, <-intf, 0, 0>)
	curva(<-2.5, -10, -1>, <-10, 0, 0>, <-intf, 0, 0>, <0, intf, 0>)
}



#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 15.0;
#declare dir_camera = < 7.00, 7.00, 7.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)