// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_peca =
  texture{
    pigment{ color rgb < 0.5, 0.5, 0.5 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.0, 0.0, 0.0 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 1.0
  }

#include "eixos.inc"

#macro interpolalin(t0, v0, t1, v1, tt)
  #local r = (tt-t0)/(t1-t0);
  #local s = 1 - r;
  #local vv = s*v0 + r*v1;
  vv
#end

#macro arcobezier(t0, t1, A, B, C, D, tt)
  #local AB = interpolalin(t0, A, t1, B, tt);
  #local BC = interpolalin(t0, B, t1, C, tt);
  #local CD = interpolalin(t0, C, t1, D, tt);

  #local ABC = interpolalin(t0, AB, t1, BC, tt);
  #local BCD = interpolalin(t0, BC, t1, CD, tt);

  #local ABCD = interpolalin(t0, ABC, t1, BCD, tt);

  ABCD
#end

#declare lado = 40;
#declare n = 1500;
#declare grossura = 1;
#declare tx = tx_fosca;

#macro Corda(grossura, lado, n, tx)
  #declare i = 0;
  #declare tt = 0;

  #while (i < n)
    #if ((tt >= 0) & (tt < 1/4))
      #declare centro = arcobezier(0, 1/4, <0,0,0>, <0.25,0,0.5>, <.5,0,.5>, <.5,0,.25>,tt);
    #end
    #if ((tt >= 1/4) & (tt < 1/2))
      #declare centro = arcobezier(1/4, 1/2, <.5,0,0.25>, <-0.2,0,-0.8>,<-0.7,0,-0.5>, <0,0,.6>, tt);
    #end
    #if ((tt >= 1/2) & (tt < 3/4))
      #declare centro = arcobezier(1/2, 3/4, <0,0,.6>, <0,0.2,-0.2>, <0,-0.2,-0.2>, <0.5,-.2,.4>, tt);
    #end
    #if ((tt >= 3/4) & (tt < 1))
      #declare centro = arcobezier(3/4, 1, <0.5,-.2,.4>, <1,0.8,-1>, <0,0.4,-0.2>, <0,0,0>, tt);
    #end
    #declare tt=tt+1/n;
    #declare i=i+1;
        sphere{ lado*centro, grossura texture {tx} }
  #end
#end

Corda(grossura, lado, n, tx)

#include "camlight.inc"
#declare centro_cena = < 6, 0, 0 >;
#declare raio_cena = 50;
#declare dir_camera = < 10.00, 30.00, 5.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)