// Last edited on 2019-07-17 03:34:59 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#macro interpolar(t0, v0, t1, v1, tt)
        #local r = (tt - t0)/(t1 - t0);
        #local s = 1 - r;
        #local vv = s*v0 + r*v1;
        vv
#end

#macro arcobezier(t0, t1, A, B, C, D, tt)
        #local AB = interpolar(t0, A, t1, B, tt);
        #local BC = interpolar(t0, B, t1, C, tt);
        #local CD = interpolar(t0, C, t1, D, tt);

        #local ABC = interpolar(t0, AB, t1, BC, tt);
        #local BCD = interpolar(t0, BC, t1, CD, tt);

        #local ABCD = interpolar(t0, ABC, t1, BCD, tt);

        ABCD
#end

#macro suavizaZ(P, n, i, vv)
        #local j = mod(i+1, n);

        #declare P[i][2] = P[i][3] - vv;
        #declare P[j][1] = P[j][0] + vv;
#end

#macro suavizaX(P, n, i)
        #local j = mod(i+1, n);
        #local vv = (P[j][1] - P[i][2])/2;
        suavizaZ(P, n, i, vv)
#end

#macro Corda(centro, n, lado)
        #declare i = 0;
        #declare tt = 0.0;

        #declare P = array[4][4];

        #declare P[0][0] = <0,0,0>;
        #declare P[0][1] = <0.2,0,0.1>;
        #declare P[0][2] = <0.1,0,0.1>;
        #declare P[0][3] = <0.5,0,0.25>;
        #declare P[1][0] = P[0][3];
        #declare P[1][1] = <-0.5,0,-0.5>;
        #declare P[1][2] = <-0.3,0,0.5>;
        #declare P[1][3] = <0.5,0,0.4>;
        #declare P[2][0] = P[1][3];
        #declare P[2][1] = <0,0.2,-0.2>;
        #declare P[2][2] = <0,0.2,-0.2>;
        #declare P[2][3] = <0.5,-0.2,-0.4>;
        #declare P[3][0] = P[2][3];
        #declare P[3][1] = <0.5,0.2,0.5>;
        #declare P[3][2] = <0,0.2, -0.2>;
        #declare P[3][3] = P[0][0];

        #while(i < 4)
                suavizaX(P, 4, i)

                #declare i = i + 1;
        #end

        union {
                #declare j = 0;
                #declare i = 0;
                #while(i < n)
                        #if ((tt >= j/4) & (tt < (j+1)/4))
                                #declare centro = arcobezier(j/4, (j+1)/4, P[j][0], P[j][1], P[j][2], P[j][3], tt);

                                sphere{ lado*centro , 0.2 texture { tx_fosca }}
                        #else
                                #declare j = j + 1;
                        #end

                        #declare tt = tt + 1/n;
                        #declare i = i + 1;
                #end
        }
#end

Corda(0, 1500, 5)

#include "eixos.inc"
//object{eixos(5)}

#include "camlight.inc"
#declare centro_cena = < 2, 1, 0 >;
#declare raio_cena = 5.5;
#declare dir_camera = < 10.00, 30.00, 5.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)