// Last edited on 2019-07-17 05:17:19 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_peca =
  texture{
    pigment{ color rgb < 0.5, 0.5, 0.5 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.0, 0.0, 0.0 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 1.0
  }

#macro interpolalin(t0, v0, t1, v1, tt)
  #local r = (tt-t0)/(t1-t0);
  #local s = 1 - r;
  #local vv = s*v0 + r*v1;
  vv
#end

#macro arcobezier(t0, t1, A, B, C, D, tt)
  #local AB = interpolalin(t0, A, t1, B, tt);
  #local BC = interpolalin(t0, B, t1, C, tt);
  #local CD = interpolalin(t0, C, t1, D, tt);

  #local ABC = interpolalin(t0, AB, t1, BC, tt);
  #local BCD = interpolalin(t0, BC, t1, CD, tt);

  #local ABCD = interpolalin(t0, ABC, t1, BCD, tt);

  ABCD
#end

#declare lado = 40;
#declare n_arcos = 4;
#declare n_bolas = 1500;
#declare grossura = 1;
#declare tx = tx_fosca;

#macro suaviza(P, n_arcos)
  #local i = 0;

  #while (i < n_arcos)
        #local j = mod(i+1, n_arcos);
        #local vv = (P[j][1] - P[i][2])/2;
        #declare P[i][2] = P[i][3] - vv;
    #declare P[j][1] = P[j][0] + vv;
    #local i = i + 1;
  #end
#end

#declare P = array[n_arcos][4];
#declare P[0][0] = <0,0,0>;
#declare P[0][1] = <0.25,0,0.5>;
#declare P[0][2] = <.7,0,.7>;
#declare P[0][3] = <.5,0,.25>;
#declare P[1][0] = P[0][3];
#declare P[1][1] = <-0.2,0,-0.8>;
#declare P[1][2] = <-0.7,-.5,-0.5>;
#declare P[1][3] = <-0.2,0,.6>;
#declare P[2][0] = P[1][3];
#declare P[2][1] = <1,.5,0>;
#declare P[2][2] = <0,2,-.5>;
#declare P[2][3] = <0.5,0,.4>;
#declare P[3][0] = P[2][3];
#declare P[3][1] = <1,0.8,-1>;
#declare P[3][2] = <0,0.4,-0.2>;
#declare P[3][3] = P[0][0];

#declare Q = array[n_arcos][4];
#declare Q[0][0] = <0,0,0>;
#declare Q[0][1] = <-0.25,0,-0.5>;
#declare Q[0][2] = <-.7,0,-.7>;
#declare Q[0][3] = <-.5,0,-.25>;
#declare Q[1][0] = Q[0][3];
#declare Q[1][1] = <0.2,0,0.8>;
#declare Q[1][2] = <0.7,.5,0.5>;
#declare Q[1][3] = <0.2,0,-.6>;
#declare Q[2][0] = Q[1][3];
#declare Q[2][1] = <-1,-.5,0>;
#declare Q[2][2] = <0,-2,.5>;
#declare Q[2][3] = <-0.5,0,-.4>;
#declare Q[3][0] = Q[2][3];
#declare Q[3][1] = <-1,-0.8,1>;
#declare Q[3][2] = <0,-0.4,0.2>;
#declare Q[3][3] = Q[0][0];

suaviza(P, n_arcos)
suaviza(Q, n_arcos)

#macro Noh(grossura, lado, P, n_bolas, tx)
  union{ 
    #local tt = 0;
    #local i = 0;
    #local j = 0;
    #while (j < n_bolas)
      #if ((tt >= i/n_arcos) & (tt < (i + 1)/n_arcos))
        #declare centro = arcobezier(i/n_arcos, (i + 1)/n_arcos, P[i][0], P[i][1], P[i][2], P[i][3], tt);
        #local tt=tt+1/n_bolas;
        #local j=j+1;
        sphere{ lado*centro, grossura texture {tx} }
          #else
            #local i=i+1;
      #end
    #end
  }
#end

#declare R = array[n_arcos][4];
#for (i, 0, n_arcos-1, 1)
  #for (j, 0, 3, 1)
    #declare R[i][j] = <0,0,0>;
  #end
#end

#macro interpolaMatriz(P, Q, n_arcos, c0, c1, cc, R)
  #local i = 0;
  #local j = 0;
  #while (i < n_arcos)
    #while (j < 4)
      #declare R[i][j] = interpolalin(c0, P[i][j], c1 , Q[i][j], cc);
      #local j = j + 1;
    #end
    #local i = i + 1;
    #local j = 0;
  #end
#end

#declare n_cenas = 4;
#macro cena(P, Q, R, grossura, lado, n_arcos, n_bolas, n_cenas, tx)
  #local i = 0;
  #while (i < n_cenas)
    interpolaMatriz(P, Q, n_arcos, 0, 1, i/n_cenas, R)
        object{ Noh(grossura, lado, R, n_bolas, tx) translate 20*i*y }
        #local i = i + 1;
  #end
#end

cena(Q, P, R, grossura, lado, n_arcos, n_bolas, n_cenas, tx)

#include "eixos.inc"
//object{ eixos(20) }

#include "camlight.inc"
#declare centro_cena = < 6, 30, 0 >;
#declare raio_cena = 55;
#declare dir_camera = < 30.00, 10.00, 5.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)